Backup MySQL databases in separate gzipped sql files on Windows

mysql-backup-windows.bat

@echo off
REM Following Script will fow on Windows 10
REM Design to take XAMPP MYSQL Backup
REM LAST UPDATE on 17-11-2017

 set dbUser=root
 set dbPassword=
 set backupDir="E:\Backup\"
 set mysqldump="E:\xampp\mysql\bin\mysqldump.exe"
 set mysqlDataDir="E:\xampp\mysql\data"
 set zip="C:\Program Files\7-Zip\7z.exe"

:: get date
 for /F "tokens=1-3 delims=- " %%i in ('date /t') do (
      set dd=%%i
      set mon=%%j
      set yy=%%k
 )

 :: get time
 for /F "tokens=5-8 delims=:. " %%i in ('echo.^| time ^| find "current" ') do (
      set hh=%%i
      set min=%%j
 )


 echo dirName=%yy%%mon%%dd%_%hh%%min%
 set dirName=%yy%%mon%%dd%_%hh%%min%
 
 :: switch to the "data" folder
 pushd %mysqlDataDir%

 :: iterate over the folder structure in the "data" folder to get the databases
 for /d %%f in (*) do (

 if not exist %backupDir%\%dirName%\ (
      mkdir %backupDir%\%dirName%
 )

 %mysqldump% --host="localhost" --user=%dbUser% --password=%dbPassword% --single-transaction --add-drop-table --databases %%f > %backupDir%\%dirName%\%%f.sql

 %zip% a -tgzip %backupDir%\%dirName%\%%f.sql.gz %backupDir%\%dirName%\%%f.sql

 del %backupDir%\%dirName%\%%f.sql
 )
 popd