Plano updated: reviewed description, opt depends, install the required files at the right place i.e avoid .git files and fix some permissions/ownership

Plano theme archlinux

# Maintainer: zach <zach {at} zach-adams {dot} com>
# Contributor: Gordian Edenhofer <gordian.edenhofer[at]yahoo[dot]de

pkgname=gtk-theme-plano-git
_pkgname=plano-theme
_pkgauthor=lassekongo83
pkgver=175.4d6a9cf
pkgrel=2
pkgdesc='A flat theme for GNOME & Xfce'
arch=('any')
url="https://github.com/${_pkgauthor}/${_pkgname}"
license=('GPL3')
depends=('gtk-engine-murrine' 'gtk-engines')
optdepends=('ttf-roboto: for the GNOME shell theme')
makedepends=('git')
source=(${_pkgname}::"git+https://github.com/${_pkgauthor}/${_pkgname}.git")
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_pkgname}"
  echo "$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

package() {
  install -d "${pkgdir}"/usr/share/themes/Plano

  for file in index.theme gnome-shell gtk-2.0 gtk-3.0 openbox-3 xfwm4
  do
    cp -R "${srcdir}/${_pkgname}/${file}" "${pkgdir}"/usr/share/themes/Plano
  done

  # fix permissions and ownership
  find "${pkgdir}"/ -type d -exec chmod 755 '{}' \;
  find "${pkgdir}"/ -type f -exec chmod 644 '{}' \;
  chown -R root.root "${pkgdir}"/*

  # install license
  install -D -m644 "${srcdir}/${_pkgname}"/LICENSE "${pkgdir}"/usr/share/licenses/"${pkgname}"/LICENSE
}