app-admin/keepass/keepass-2.19.ebuild

app-adminkeepasskeepass-2.19.ebuild.sh

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit eutils fdo-mime mono multilib


MY_PN="KeePass"
DESCRIPTION="A free, open source, light-weight and easy-to-use password manager"
HOMEPAGE="http://keepass.info/"
SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-${PV}-Source.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="aot autotype"

RDEPEND=">=dev-lang/mono-2.10.5"
DEPEND="${RDEPEND}
	app-arch/unzip"

S=${WORKDIR}

src_prepare() {
	# Remove Windows-specific things
	pushd Build || die
	. PrepMonoDev.sh || die
	popd || die

	# sgen not available on mono
	epatch "${FILESDIR}/${PN}-2.19-skip-sgen-if-unix.patch"
	# KeePass looks for some XSL files in the same folder as the executable,
	# we prefer to have it in /usr/share/KeePass
	epatch "${FILESDIR}/${PN}-2.19-xsl-path-detection.patch"
}

src_compile() {
	# Build with Release target
	xbuild /target:KeePass /property:Configuration=Release || die

	# Run Ahead Of Time compiler on the binary
	if use aot; then
		mono --aot -O=all Build/KeePass/Release/KeePass.exe || die
	fi
}

src_install() {
	# Wrapper script to launch mono
	make_wrapper ${PN} "mono /usr/$(get_libdir)/${PN}/KeePass.exe"

	# Some XSL files
	insinto /usr/share/${PN}/XSL
	doins Ext/XSL/*

	insinto /usr/$(get_libdir)/${PN}/
	exeinto /usr/$(get_libdir)/${PN}/
	doins Ext/KeePass.exe.config
	# Default configuration, simply says to use user-specific configuration
	doins Ext/KeePass.config.xml

	# The actual executable
	doexe Build/KeePass/Release/KeePass.exe

	# Copy the AOT compilation result
        if use aot; then
                doexe Build/KeePass/Release/KeePass.exe.so
        fi

	# Prepare the icon
	newicon -s 256 Ext/Icons/Finals/plockb.png "${PN}.png"

	# Create a desktop entry
	make_desktop_entry ${PN} ${MY_PN} ${PN} "Security"

	# MIME descriptor for .kdbx files
	insinto /usr/share/mime/packages/
	doins "${FILESDIR}/${PN}.xml"
}

pkg_postinst() {
	fdo-mime_mime_database_update
        fdo-mime_desktop_database_update

	elog "Optional dependencies:"
	elog "	x11-misc/xdotool (enables autotype)"
}