Meme PKGBUILD

PKGBUILD

#Contributor: allencch <allencch at hotmail dot com>
#Contributor: Charles E. Vejnar
pkgname=meme
pkgver=4.10.0_1
pkgrel=1
pkgdesc="The MEME suite provides tools for discovering and using protein and DNA sequence motifs"
arch=("i686" "x86_64")
url="http://meme.sdsc.edu/meme/intro.html"
license=("custom")
depends=(perl-html-template tcsh python2)
source=("http://ebi.edu.au/ftp/software/MEME/4.9.1/${pkgname}_${pkgver}.tar.gz"
        "python27.patch")
sha1sums=("47db8717a61b9fb11cf6069ab33b17e1bbe58085"
          "2d33af63abc2865abeb5f59b19da811667128732")

prepare() {
    cd $srcdir/${pkgname}_${pkgver%_*}

    patch -p1 -i "${srcdir}/python27.patch"
}

build() {
    cd $srcdir/${pkgname}_${pkgver%_*}

    ./configure --prefix=/usr --program-prefix="meme-" --docdir='${prefix}'/usr/share/doc/meme --sysconfdir='${prefix}'/../etc/meme --with-python=/usr/bin/python2.7

    make
}

package() {
        cd "${srcdir}/${pkgname}_${pkgver%_*}"

    make prefix="${pkgdir}/usr" install

    # Move Python module to a more standard location
    install -dm755 ${pkgdir}/usr/lib/python2.7/site-packages
    for fname in $(ls -1 ${pkgdir}/usr/lib/python2.7/); do
        if [[ $fname = *.py ]]; then
            mv ${pkgdir}/usr/lib/python2.7/$fname ${pkgdir}/usr/lib/python2.7/site-packages/${fname#meme-}
        fi
    done
}

python27.patch

--- a/scripts/Makefile.in
+++ b/scripts/Makefile.in
@@ -548,7 +548,7 @@
   hypergeometric.py \
   sequence.py
 
-pythonlibdir = $(libdir)/python
+pythonlibdir = $(libdir)/python2.7
 pythonlib_SCRIPTS = \
   $(BUILT_PYTHON_LIB) \
   $(NORMAL_PYTHON_LIB)