PKGBUILD

PKGBUILD.txt

# Maintainer: Stanislav GE <ginermail@gmail.com>

pkgname=doublecmd-svn
pkgver=5152
pkgrel=1
pkgdesc="Double Commander is a cross platform open source file manager with two panels side by side. It is inspired by Total Commander and features some new ideas."
arch=(i686 x86_64)
url=http://doublecmd.sourceforge.net
license=(GPL2)
makedepends=('lazarus' 'fpc' 'subversion')
_svnmod=doublecmd-code
source=('doublecmd-code::svn://svn.code.sf.net/p/doublecmd/code/trunk')
md5sums=('SKIP')

pkgver() {
    cd "$SRCDEST/$_svnmod"
    svnversion
}

build() {
    cd $srcdir/$_svnmod
    ./build.sh beta
}

package() {
    cd $srcdir/$_svnmod
    # create doublecmd link to /usr/bin
    prefix=/opt/doublecmd
    install -d $pkgdir/usr/bin
    ln -s $prefix/doublecmd $pkgdir/usr/bin/doublecmd

    # install desktop file and icon
    install -D -m 644 install/linux/doublecmd.desktop $pkgdir/usr/share/applications/doublecmd.desktop
    install -D -m 644 doublecmd.png $pkgdir/usr/share/pixmaps/doublecmd.png

    # install plugins
    for plugin in plugins/wcx/*/lib/*.wcx \
            plugins/wdx/*/lib/*.wdx \
            plugins/wlx/*/lib/*.wlx \
            plugins/dsx/*/lib/*.dsx \
            plugins/wfx/*/lib/*.wfx \
            ; do
        dest_plugin_path=$(echo $pkgdir/$prefix/$plugin|sed 's/\/lib\//\//')
        install -D -m 644 $plugin $dest_plugin_path
    done

    # install doc, language, pixmaps
    cp -r doc $pkgdir/$prefix/doc
    cp -r language $pkgdir/$prefix/language
    cp -r pixmaps $pkgdir/$prefix/pixmaps

    # install bin, misc
    install -D -m 755 doublecmd $pkgdir/$prefix
    install -D -m 644 install/linux/doublecmd.xml doublecmd.ext.example \
        pixmaps.txt multiarc.ini  $pkgdir/$prefix
}