title

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title SPEAR & CRATE
again_interval 0.1
verbose_logging

========
OBJECTS
========

Background
DarkBlue

Hole
Black

Wall
DarkRed

PlayerUp
LightBrown Red Brown
.02..
110..
111..
111..
2.2..

SpearUp
LightGrey Red Brown
..0..
..1..
..2..
..2..
..2..

PlayerDown
LightBrown Red Brown
...0.
..111
..201
..011
..2.2

SpearDown
LightGrey Red Brown
..2..
..2..
..2..
..1..
..0..

PlayerLeft
LightBrown Red Brown
..0..
.111.
02221
.110.
.2.2.

SpearLeft
LightGrey Red Brown
.....
.....
01222
.1...
.....

PlayerRight
LightBrown Red Brown
..0..
.111.
12220
.011.
.2.2.

SpearRight
LightGrey Red Brown
.....
.....
22210
...1.
.....

CrateAny
DarkGrey LightGreen
00.00
01.10
.....
01.10
00.00

CrateH
DarkGrey Blue
00000
01110
.....
01110
00000

CrateV
DarkGrey Yellow
00.00
01.10
01.10
01.10
00.00

Falling
DarkGrey
.....
.....
..0..
.....
.....

=======
LEGEND
=======

Player = PlayerUp or PlayerDown or PlayerLeft or PlayerRight
Spear = SpearUp or SpearDown or SpearLeft or SpearRight
Crate = CrateAny or CrateH or CrateV
Falls = Player or Crate

_ = Hole
. = Background
▒ = Wall
▲ = PlayerUp
▼ = PlayerDown
◄ = PlayerLeft
► = PlayerRight
↑ = SpearUp
↓ = SpearDown
← = SpearLeft
→ = SpearRight
╬ = CrateAny
═ = CrateH
║ = CrateV

=======
SOUNDS
=======

Falling create 38545107

================
COLLISIONLAYERS
================

Background
Hole
Player, Spear, Wall
Crate, Falling

======
RULES
======

( Move the spear straight forwards and backwards )
[ parallel Player | Spear ] -> [ parallel Player | parallel Spear ]

( Pull a crate if spear stuck in it )
[ ^ Player | stationary Spear Crate ] -> [ ^ Player | ^ Spear ^ Crate ]
[ v Player | stationary Spear Crate ] -> [ v Player | v Spear v Crate ]

( Rotate the spear if no crate )
[ ^ Player | stationary Spear ] -> [ ^ Player | < Spear ]
[ v Player | stationary Spear ] -> [ v Player | < Spear ]

( Push crates with the player )
[ > Player | Crate ] -> [ > Player | > Crate ]

( Rotate the spear and player )
late up [ Player | Spear ] -> [ PlayerUp | SpearUp ]
late down [ Player | Spear ] -> [ PlayerDown | SpearDown ]
late left [ Player | Spear ] -> [ PlayerLeft | SpearLeft ]
late right [ Player | Spear ] -> [ PlayerRight | SpearRight ]

( Crate shouldn't overlap )
[ > Crate | Crate ] -> cancel
[ > Crate | Wall ] -> cancel
late [ Player Crate ] -> cancel
late [ SpearUp CrateH ] -> cancel
late [ SpearDown CrateH ] -> cancel
late [ SpearLeft CrateV ] -> cancel
late [ SpearRight CrateV ] -> cancel

( Things fall in holes )
late [ Crate Hole no Spear ] -> again
late [ Player Hole ] -> again
( Remove spear when player falls in hole )
[ Player Hole | Spear ] -> [ Player Hole | ]
( Animate falling )
[ Falling Hole ] -> [ Hole ]
[ stationary Falls Hole ] -> [ Falling Hole ] again

==============
WINCONDITIONS
==============

=======
LEVELS
=======

.......
.▒▒▒▒▒.
▒▒.╬.▒▒
►→.╬...
▒▒.╬.▒▒
.▒▒▒▒▒.
.......

.......
.▒▒▒▒▒.
▒▒.╬.▒▒
►→.╬...
▒▒.╬.▒▒
.▒▒▒▒▒.
.......