Instantly share code, notes, and snippets.

anonymous /gist:7225d966e3ffc3eaff1a
Created Sep 17, 2014

Embed
What would you like to do?
// gif by dave whyte >:)
int[][] result;
float t;
float ease(float p) {
return 3*p*p - 2*p*p*p;
}
float ease(float p, float g) {
if (p < 0.5)
return 0.5 * pow(2*p, g);
else
return 1 - 0.5 * pow(2*(1 - p), g);
}
float mn = .5*sqrt(3);
void setup() {
setup_();
result = new int[width*height][3];
}
void draw() {
if(!recording){
t = mouseX*1.0/width;
draw_();
}
else {
for (int i=0; i<width*height; i++)
for (int a=0; a<3; a++)
result[i][a] = 0;
for (int sa=0; sa<samplesPerFrame; sa++) {
t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
draw_();
loadPixels();
for (int i=0; i<pixels.length; i++) {
result[i][0] += pixels[i] >> 16 & 0xff;
result[i][1] += pixels[i] >> 8 & 0xff;
result[i][2] += pixels[i] & 0xff;
}
}
loadPixels();
for (int i=0; i<pixels.length; i++)
pixels[i] = 0xff << 24 |
int(result[i][0]*1.0/samplesPerFrame) << 16 |
int(result[i][1]*1.0/samplesPerFrame) << 8 |
int(result[i][2]*1.0/samplesPerFrame);
updatePixels();
saveFrame("f###.png");
if (frameCount==numFrames)
exit();
}
}
//////////////////////////////////////////////////////////////////////////////
int samplesPerFrame = 16;
int numFrames = 120;
float shutterAngle = .8;
boolean recording = true;
void setup_() {
size(500,500,P3D);
rectMode(CENTER);
fill(32);
noStroke();
ortho();
}
float x, y, z, tt;
float r = 180;
int N = 600;
float d;
float th;
void draw_() {
background(24);
pushMatrix();
translate(width/2, height/2);
for(int i=0; i<N; i++){
th = PI*1.2*i/(N-1) + TWO_PI*t;
d = map(cos(TWO_PI*i/(N-1)),1,-1,12,24);
x = r*sin(2*th);
y = .75*r*sin(3*th);
z = 20*sin(17*th+HALF_PI);
pushMatrix();
translate(x,y,z);
fill(lerpColor(#ff00cc,#00ccff,ease(i/float(N))));
ellipse(0,0,d,d);
popMatrix();
}
popMatrix();
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment