sphere worms

sphere.pde

// by davey aka bees & bombs :)

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 280;        
float shutterAngle = .6;

boolean recording = false;

void setup() {
  size(540, 540, P3D);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
}

float x, y, z, tt;
int N = 300;
float R = 180;

void draw_() {
  background(0);
  noStroke();
  push();
  translate(width/2, height/2);
  sphereDetail(8);
  for (int a=0; a<8; a++) {
    for (int i=0; i<N; i++) {
      fill(255);
      randomSeed(12345*i+23456);
      y = random(R*.95, R*.99);
      x = sqrt(R*R-y*y);

      push();
      rotateX(random(TWO_PI));
      rotate(random(TWO_PI));
      rotateY(random(TWO_PI));
      rotateX(random(TWO_PI));
      rotate(random(TWO_PI));
      rotateY(TWO_PI*(t+.04*a) + random(TWO_PI));
      translate(x, y, 0);
      sphere(.32*a);
      pop();
    }
  }
  sphereDetail(24);
  fill(0);
  sphere(R);
  pop();
}