fliers — http://tmblr.co/ZOLwww1Pfhn6W

gistfile1.pde

// by david >:)

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("g###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 32;
int numFrames = 200;        
float shutterAngle = .5;

boolean recording = false;

void setup_() {
  size(500, 500, P3D);
  smooth(8);
  fill(0);
  noStroke();
}

float x, y, z, tt;
int N = 64;
float d;
float r = 130;
float th, ph, tw;

void draw_() {
  background(255); 
  pushMatrix();
  translate(width/2, height/2);
  rotate(HALF_PI);
  for (int a=0; a<9; a++) {
    pushMatrix();
    tt = t - 0.005*a;
    d = 5*exp(-.1*a);
    tw = PI*1.8*cos(TWO_PI*tt);
    rotateY(TWO_PI*tt-PI*2/3);
    for (int i=0; i<N; i++) {
      th = (i+N/2*tt)*TWO_PI/N;
      x = r*cos(th);
      ph = cos(th)*tw;
      y = r*sin(th)*cos(ph);
      z = r*sin(th)*sin(ph);
      pushMatrix();
      translate(x, y, z);
      rotateY(-TWO_PI*tt+PI*2/3);
      ellipse(0, 0, d, d);
      popMatrix();
    }
    popMatrix();
  }
  popMatrix();
}