counterrotation — http://drbl.in/moei

gistfile1.pde

// by dw

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("f###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 120;        
float shutterAngle = .6;

boolean recording = true;

void setup_() {
  size(800,600);
  rectMode(CENTER);
  fill(32);
  noStroke();
}

float x, y, tt;
int N = 12;
float maxDiam = 60, minDiam = 20, diam;
float phase;
float angle;

void draw_() {
  fill(200,50,30); 
  pushMatrix();
  translate(width/2, height/2);
  background(248);
  for(int i=0; i<12; i++){
    angle = (i-t)*TWO_PI/12;
    pushMatrix();
    rotate(angle);
    phase = map(cos(angle-TWO_PI*t),-1,1,0,1);
    fill(lerpColor(color(224,149,139),color(200,50,30),min(1.25*phase,1)));
    diam = map(ease(phase,2),0,1,minDiam,maxDiam);
    ellipse(140,0,diam,diam);
    popMatrix();
  }
  popMatrix();
}