columns

gistfile1.pde

// by david @ bees & bombs

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 12;
int numFrames = 200;        
float shutterAngle = .5;

boolean recording = true;

void setup_() {
  size(500, 500, P3D);
  rectMode(CENTER);
  noStroke();
  smooth(8);
}

float x, y, tt;
float l = 31;
int N = 4;
float h1, h2;

color c1 = color(32), c2 = color(250,50,32), c3 = color(250);

void column(float h) {
  fill(c3);
  pushMatrix();
  translate(0, 0, h);
  rect(0,0,l,l);
  popMatrix();
  fill(c1);
  pushMatrix();
  translate(0,-l/2,h/2);
  rotateX(HALF_PI);
  rect(0,0,l,h);
  popMatrix();
  pushMatrix();
  translate(0,l/2,h/2);
  rotateX(HALF_PI);
  rect(0,0,l,h);
  popMatrix();
  fill(c2);
  pushMatrix();
  rotate(HALF_PI);
  translate(0,l/2,h/2);
  rotateX(HALF_PI);
  rect(0,0,l,h);
  popMatrix();
  pushMatrix();
  rotate(-HALF_PI);
  translate(0,l/2,h/2);
  rotateX(HALF_PI);
  rect(0,0,l,h);
  popMatrix();
}

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2 + 70, -120);
  rotateX(PI*.32);
  rotate(PI*t+PI*1.25);
  for (int i=-N; i<=N; i++) {
    for (int j=-N; j<=N; j++) {
      pushMatrix();
      translate(i*l,j*l);
      tt = constrain(2.5*t - 1.5*(0+dist(i,j,0,0)/(N*sqrt(2))),0,1);
      h1 = map(i+j,-2*N,2*N,l*.5,l*8.5);
      h2 = map(-i-j,-2*N,2*N,l*.5,l*8.5);
      column(lerp(h1,h2,ease(tt,4.5)));
      popMatrix();
    }
  }
  popMatrix();
}