mingw-w64-gnome-themes-standard 3.14.2.3-1

PKGBUILD

pkgname=mingw-w64-gnome-themes-standard
pkgver=3.14.2.3
pkgrel=1
pkgdesc="Default themes for the GNOME desktop (mingw-w64)"
arch=(any)
url="http://www.gnome.org"
license=(GPL2)
options=('!strip' '!buildflags' '!libtool' 'staticlibs')
depends=('mingw-w64-librsvg')
makedepends=('mingw-w64-configure' 'mingw-w64-gtk3>=3.14.0' 'mingw-w64-gtk2>=2.24.15' 'librsvg' 'gdk-pixbuf2' 'intltool' 'gtk3')
source=("http://ftp.gnome.org/pub/gnome/sources/gnome-themes-standard/${pkgver:0:4}/gnome-themes-standard-${pkgver}.tar.xz")
md5sums=('d2af109b0f6b04447d79b10d517cd5fa')

_architectures="i686-w64-mingw32 x86_64-w64-mingw32"


build() {
  cd "${srcdir}/gnome-themes-standard-${pkgver}"
  
  export CFLAGS="-O2 -mms-bitfields"
  unset LDFLAGS
  
  for _arch in ${_architectures}; do
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-configure \
      --disable-nls
    make
    popd
  done
}


package() {
  for _arch in ${_architectures}; do
    cd "${srcdir}/gnome-themes-standard-${pkgver}/build-${_arch}"
    make -j1 DESTDIR="$pkgdir" install

    # stuff useless for MS Windows
    rm -r "$pkgdir/usr/$_arch/share/themes/Adwaita/metacity-1"
    rm -r "$pkgdir/usr/$_arch/share/themes/HighContrast/metacity-1"
  done
}