s4cmd-python3-git

.SRCINFO

pkgbase = s4cmd
	pkgdesc = Super S3 command line tool (git) for Python 3
	pkgver = 66.f5f5ff0
	pkgrel = 1
	url = https://github.com/bloomreach/s4cmd
	arch = any
	license = GPL
	makedepends = git
	makedepends = python-setuptools
	depends = python
	depends = python-dateutil
	depends = python-boto3
	optdepends = gnupg: encrypted file storage
	provides = s4cmd
	conflicts = s4cmd
	source = git+https://github.com/bloomreach/s4cmd.git
	source = setup.py.patch
	md5sums = SKIP
	md5sums = ed8297a6a6b3c727e435ad9385eed02a

pkgname = s4cmd-python3-git

PKGBUILD

# Maintainer: apetresc <apetresc at gmail dot com>
# Contributor: realitygaps <realitygaps at yahoo dot com>

pkgbase=s4cmd
pkgname=${pkgbase}-python3-git
pkgver=66.f5f5ff0
pkgrel=1
pkgdesc="Super S3 command line tool (git) for Python 3"
arch=('any')
url="https://github.com/bloomreach/${pkgbase}"
license=('GPL')
depends=('python' 'python-dateutil' 'python-boto3')
makedepends=(git python-setuptools)
optdepends=('gnupg: encrypted file storage')
provides=('s4cmd')
conflicts=('s4cmd')
source=("git+${url}.git" "setup.py.patch")
md5sums=('SKIP'
         'ed8297a6a6b3c727e435ad9385eed02a')

prepare() {
  patch -uN "${srcdir}/${pkgbase}/setup.py" "${srcdir}/setup.py.patch"
}

pkgver() {
	 cd "${srcdir}/${pkgbase}"
	 local ver="$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
	 printf "%s" "${ver//-/.}"
}

package() {
  cd "${srcdir}/${pkgbase}"
  python setup.py install --root="$pkgdir"
}

setup.py.patch

--- setup.py.old	2017-04-18 11:32:55.934591357 -0400
+++ setup.py	2017-04-18 11:33:06.231258363 -0400
@@ -31,15 +31,11 @@
 __maintainer__ = __author__
 __status__ = "Development"
 
-def _post_install():
-  os.chmod("/etc/bash_completion.d/s4cmd",755)
 
 class install(_install):
   def run(self):
     _install.run(self)
-    mode = stat.S_IREAD | stat.S_IWRITE | stat.S_IRGRP | stat.S_IROTH
-    os.chmod("/etc/bash_completion.d/s4cmd", mode)
-    
+
 
 setup(name='s4cmd',
       version=__version__,