Starlink yakima mount

starlink-yakima-mount.scad

$fn=64;

use <./thumbscrew.scad>;

eps=0.01;

// https://yakimasupport.zendesk.com/hc/en-us/articles/360042356131-What-are-the-dimensions-of-your-track-
channelW = 20;
channelH = 3;
trackW = 30;
trackGapH = 1;
trackGapW = 10;

baseR = 34.29/2;
wallThickness = 4;
baseD = 57;

notchW = 11;
notchD = 12;

c = 6;

holeW = 12.2 * 1.2;
holeH = holeW;
holeHOffset = 5;
holeFillet = 1;

thumbR = 15;
boltR = (9.52 / 2) * 1.10; // 3/8" d
boltGap = max(10, thumbR-boltR)+5;
endGap = 6;

l = 2 * (baseR+wallThickness+boltGap+(boltR*2)+endGap);
w = max(channelW, (baseR+wallThickness) * 2);

module fillet(r) {
    offset(r=r) offset(r=-r) children();
}

module boltHole() {
    translate([0, baseR+wallThickness+boltR+boltGap, 0]) {
        cylinder(h=100, r=boltR, center=true);
        translate([0, 0, 100/2]) {
            cylinder(h=100, r=thumbR, center=true);
        }
        linear_extrude(100) {
            polygon(points=[
                [thumbR, boltR+endGap+eps],
                [thumbR, 0],
                [-(thumbR), 0],
                [-(thumbR), boltR+endGap+eps],
            ]);
        }
    }
}

module drainHole() {
    translate([0, 0, 5]) {
        rotate([0, -90-15, 0]) {
            cylinder(h=1000, r=5);
        }
    }
}

difference() {
    union() {
        difference() {
            union() {
                // post
                cylinder(h=baseD+c*2, r=baseR+wallThickness);

                // base
                difference() {
                    union() {
                        translate([0, 0, -trackGapH/2]) {
                            cube([trackGapW, l, trackGapH], center=true);
                        }

                        difference() {
                            rotate([90, 0, 0]) {
                                cylinder(h=l, r=w/2, center=true);
                            }
                            translate([0, 0, -w/2]) {
                                cube([w, l+eps, w], center=true);
                            }
                        }
                    }

                    translate([0, 0, c]) {
                        boltHole();
                        mirror([0, 1, 0]) {
                            boltHole();
                        }
                    }
                }
            }

            translate([0, 0, c*2]) {
                translate([0, 0, baseD-(holeH/2)-holeHOffset]) {
                    rotate([0, -90, 0]) {
                        linear_extrude(wallThickness + baseR) {
                            fillet(r=1) {
                                square([holeW, holeH], center=true);
                            }
                        }
                    }
                }
                cylinder(h=baseD+eps, r=baseR);
            }
        }

        // base notch
        linear_extrude(baseD+c*2) {
            translate([baseR-notchD/2, 0, 0]) {
                fillet(r=1) square([notchD, notchW], center=true);
            }
        }
    }

    translate([0, 0, c*2]) {
        drainHole();
        mirror([1, 0, 0]) {
            drainHole();
        }
    }
}

translate([50, 0, 0]) {
    thumbscrew(10, 25, thumbR+2, 20, 18.5/2, 15, boltR);

    translate([0, 40, 0]) {
        thumbscrew(10, 25, thumbR+2, 20, 18.5/2, 15, boltR);
    }
}

thumbscrew.scad

$fn=64;

module thumbscrew(baseR, baseH, wingR, wingH, nutR, nutH, boltR) {
    difference() {
        union() {
            translate([0, 0, baseH/2]) {
                cylinder(r=baseR, h=baseH, center=true);
            }
            translate([0, 0, baseH/2]) {
                rotate([90, 0, 0]) {
                    translate([0, 0, -2]) {
                        linear_extrude(4) {
                            offset(2) offset(-2) {
                                difference() {
                                    polygon(points=[[baseR, 0], [wingR, wingH], [-wingR, wingH], [-baseR, 0]]);
                                    translate([0, wingH*1.2, 0]) {
                                        circle(r=baseR);
                                    }
                                }
                            }
                        }
                    }
                }
            }
        }
        cylinder(r=boltR, h=1000);
        translate([0, 0, baseH-nutH]) {
            cylinder(r=nutR, h=wingH+baseH, $fn=6);
        }
    }
}

thumbscrew(10, 12, 20, 16, 5, 4, 2);