Projector shaders without fixed function

Projector Light.shader

Shader "Projector/Light" { 
Properties {
	_Color ("Main Color", Color) = (1,1,1,1)
	_ShadowTex ("Cookie", 2D) = "" {}
	_FalloffTex ("FallOff", 2D) = "" {}
}

Subshader {
	Pass {
		ZWrite Off
		Fog { Color (0, 0, 0) }
		ColorMask RGB
		Blend DstColor One
		Offset -1, -1

		CGPROGRAM
		#pragma vertex vert
		#pragma fragment frag
		#include "UnityCG.cginc"
		struct v2f {
			float4 uvShadow : TEXCOORD0;
			float4 uvFalloff : TEXCOORD1;
			float4 pos : SV_POSITION;
		};
		float4x4 _Projector;
		float4x4 _ProjectorClip;
		v2f vert (float4 vertex : POSITION)
		{
			v2f o;
			o.pos = mul (UNITY_MATRIX_MVP, vertex);
			o.uvShadow = mul (_Projector, vertex);
			o.uvFalloff = mul (_ProjectorClip, vertex);
			return o;
		}
		fixed4 _Color;
		sampler2D _ShadowTex;
		sampler2D _FalloffTex;
		fixed4 frag (v2f i) : SV_Target
		{
			fixed4 texS = tex2Dproj (_ShadowTex, UNITY_PROJ_COORD(i.uvShadow));
			texS.rgb *= _Color.rgb;
			texS.a = 1.0-texS.a;

			fixed4 texF = tex2Dproj (_FalloffTex, UNITY_PROJ_COORD(i.uvFalloff));
			fixed4 res = texS * texF.a;
			return res;
		}
		ENDCG
	}
}
}

Projector Multiply.shader

Shader "Projector/Multiply" { 
	Properties {
		_ShadowTex ("Cookie", 2D) = "gray" {}
		_FalloffTex ("FallOff", 2D) = "white" {}
	}
	Subshader {
		Tags {"Queue"="Transparent"}
		Pass {
			ZWrite Off
			Fog { Color (1, 1, 1) }
			AlphaTest Greater 0
			ColorMask RGB
			Blend DstColor Zero
			Offset -1, -1

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			struct v2f {
				float4 uvShadow : TEXCOORD0;
				float4 uvFalloff : TEXCOORD1;
				float4 pos : SV_POSITION;
			};
			float4x4 _Projector;
			float4x4 _ProjectorClip;
			v2f vert (float4 vertex : POSITION)
			{
				v2f o;
				o.pos = mul (UNITY_MATRIX_MVP, vertex);
				o.uvShadow = mul (_Projector, vertex);
				o.uvFalloff = mul (_ProjectorClip, vertex);
				return o;
			}
			sampler2D _ShadowTex;
			sampler2D _FalloffTex;
			fixed4 frag (v2f i) : SV_Target
			{
				fixed4 texS = tex2Dproj (_ShadowTex, UNITY_PROJ_COORD(i.uvShadow));
				texS.a = 1.0-texS.a;

				fixed4 texF = tex2Dproj (_FalloffTex, UNITY_PROJ_COORD(i.uvFalloff));
				fixed4 res = lerp(fixed4(1,1,1,0), texS, texF.a);
				return res;
			}
			ENDCG
		}
	}
}

Thanks for sharing these! For some reason it doesn't work with Tiling of the Texture ... is simply ignored.