Filtrar por latitud y longitud un conjunto de datos utilizando el programa "NCO" (NetCDF operators - http://nco.sourceforge.net).

filtrar_datos_por_lat_y_long.bat

@echo off 

REM   Cambiar las siguientes variables con los directorios de los datos, 
REM   donde desean guardar los archivos procesados, y el directorio donde se encuentra el programa NCO.
REM   Nota importante: Los nombres de archivos y directorios no deben contener espacios!
SET data_dir=E:\MISRdata\MISR_DATA
SET processed_dir=E:\MISRdata\procesados
SET nco_dir=C:\nco
SET lat_ini=18.0
SET lat_fin=23.0
SET long_ini=-106.25
SET long_fin=-95.0



REM  Inicia el procesamiento.
SET /A count = 0
PATH=%PATH%;%nco_dir%

FOR /R   %data_dir%   %%G   IN (*.nc *.hdf) DO (
    SET /A count = count + 1
)

ECHO: Total files to be processed: %count%

PAUSE

ECHO: Recreate folder structure..

XCopy  %data_dir% %processed_dir%  /T /E

ECHO: Done...
ECHO: Preparing to process data...

PAUSE

SETLOCAL ENABLEDELAYEDEXPANSION

FOR /R   %data_dir% %%G IN (*.nc *.hdf) DO (
    set filename=%%G
    REM ECHO: !filename!
    set filename=!filename:%data_dir%\=!

    ECHO: processing %%G
    ECHO: %processed_dir%\!filename!
    
    REM Esta linea es la que realiza el filtrado.
    ncks -d Latitude,%lat_ini%,%lat_fin% -d Longitude,%long_ini%,%long_fin%    %%G  %processed_dir%\!filename!
    
    
    REM PAUSE
)

ECHO: Done processing!

PAUSE