modifiers.clj

(definterface IModifier
  (op [])
  (value []))

(deftype ABuff [^long n]
  IModifier
  (op [_] (fn [m] (long (+ n m))))
  (value [_] n)

  Object
  (toString [_] (format "#mod/+ %d" n)))

(deftype ADebuff [^long n]
  IModifier
  (op [_] (fn [m] (long (max 0 (- m n)))))
  (value [_] n)

  Object
  (toString [_] (format "#mod/- %d" n)))

(deftype AMultiplier [^long n]
  IModifier
  (op [_] (fn [m] (long (* n m))))
  (value [_] n)

  Object
  (toString [_] (format "#mod/* %d" n)))

(deftype ADivider [^long n]
  IModifier
  (op [_] (fn [m] (Math/floor (double (/ (double m) (double n))))))
  (value [_] n)

  Object
  (toString [_] (format "#mod// %d" n)))

(defmethod print-method IModifier [o ^Writer w]
  (.write w (.toString ^IModifier o)))

(def ^:private class->n
  {AMultiplier 0, ADivider 1, ABuff 2, ADebuff 3})

(defn compare-modifiers [a b]
  {:pre [(instance? IModifier a)
         (instance? IModifier b)]}
  (compare (class->n (class a))
           (class->n (class b))))

(defn apply-modifiers [modifiers n]
  (->> modifiers
       (sort-by identity compare-modifiers)
       (reduce (fn [n mod]
                 ((.op ^IModifier mod) n)) n)))