User choosers a folder; browser reads files (in cljs)

cljs-multiple-file-reader.cljs

;; uses hiccups/render-html


(defn new-window-document []
  (.. js/window open -document))
                  
(defn folder-chooser [id]
  [:input {:id id
           :type "file"
           :webkitdirectory ""
           :mozdirectory ""
           :directory ""}])
           
                     
(defn page-html []
  (render-html [:html [:head [:title "Multiple files"]]
                      [:body [:p (folder-chooser "file_input")]]]))
                     
(defn create-page []
  (doto (new-window-document)
    (.writeln (page-html))))
                     
(defn respond-to-folder-choice [input callback]
  (.addEventListener input "change"
                     #(-> % .-target .-files callback) false))
            
(defn show-page [callback]
  (let [doc (create-page)]
    (respond-to-folder-choice (.getElementById doc "file_input")
                              callback)))
                     
(defn print-files [file-list]
  (dotimes [i (.-length file-list)]
    (println (-> file-list (.item i) .-name))))
                     
(defn run-experiment []
  (show-page print-files))