ratpack + gradle + docker

gistfile1.txt

buildscript {
        repositories {
                jcenter()
        }
        dependencies {
                classpath 'io.ratpack:ratpack-gradle:0.9.13'
                classpath 'com.github.jengelman.gradle.plugins:shadow:1.2.0'
                classpath 'com.bmuschko:gradle-docker-plugin:2.0'
        }
}

apply plugin: "io.ratpack.ratpack-java"
apply plugin: "com.github.johnrengelman.shadow"

version = '1.0'

import com.bmuschko.gradle.docker.tasks.image.Dockerfile
import com.bmuschko.gradle.docker.tasks.image.DockerBuildImage
import com.bmuschko.gradle.docker.tasks.image.DockerTagImage
import com.bmuschko.gradle.docker.tasks.image.DockerPushImage
import com.bmuschko.gradle.docker.tasks.container.DockerCreateContainer
import com.bmuschko.gradle.docker.tasks.container.DockerStartContainer
import com.bmuschko.gradle.docker.tasks.container.DockerStopContainer

def registryUrl = 'localhost:5000'


docker {
        url = 'unix:///var/run/docker.sock'
        registry {
                url = 'http://' + registryUrl + '/v1'
        }
}

task buildDocker(type: DockerBuildImage) {
        dependsOn shadowJar
        inputDir = project.projectDir
        tag = "propel/$project.name:$project.version"
}

task tagDocker(type: DockerTagImage) {
        dependsOn buildDocker
        force = true
        imageId = buildDocker.getTag()
        repository = "$registryUrl/$project.name"
        tag = "$project.version"
}

task pushDocker(type: DockerPushImage ) {
        dependsOn tagDocker
        imageName = "$registryUrl/$project.name"
}

task createDocker(type: DockerCreateContainer) {
        dependsOn buildDocker
        imageId = buildDocker.getTag()
}

task runDocker(type: DockerStartContainer) {
        dependsOn createDocker
        targetContainerId { createDocker.getContainerId() }
}

task stopDocker(type: DockerStopContainer) {
        dependsOn createDocker
        targetContainerId { createDocker.getContainerId() }
}