Script to find conflicting .NET assembly references

FindConflictingReferences.fsx

// translated to F# Script from https://gist.github.com/brianlow/1553265

open System.IO
open System.Reflection

type Reference = {
    Assembly : AssemblyName
    ReferencedAssembly : AssemblyName
}

let getAllAssemblyRefs path = seq {
    let searchDir = DirectoryInfo(path)
    for file in searchDir.EnumerateFiles("*.*", SearchOption.AllDirectories) do
        if file.Extension = ".exe" || file.Extension = ".dll" then 
            let asm = Assembly.LoadFile(file.FullName)
            for referencedAsm in asm.GetReferencedAssemblies () do
                yield { Assembly = asm.GetName (); ReferencedAssembly = referencedAsm }
}

let refsWithSameShortNameButDifferentFullName assemblyRefs =
    assemblyRefs
    |> Seq.groupBy (fun ref -> ref.ReferencedAssembly.Name)
    |> Seq.filter (fun (_,refs) -> 
        let refCount = 
            refs
            |> Seq.distinctBy (fun ref -> ref.ReferencedAssembly.FullName)
            |> Seq.length
        refCount > 1)

let printPossibleConflict (name,assemblyRefs) =
    printfn "Possible conflicts for %s" name
    for ref in assemblyRefs do
        printfn "%s references %s" (ref.Assembly.Name.PadRight 40) (ref.ReferencedAssembly.FullName)
    printfn ""

let findPossibleConflicts path exclude =
    getAllAssemblyRefs path
    |> Seq.filter (fun ref -> not (exclude |> Seq.exists ((=) ref.ReferencedAssembly.Name)))
    |> refsWithSameShortNameButDifferentFullName
    |> Seq.iter printPossibleConflict

findPossibleConflicts 
    @"C:\code\<solution>\<project>\bin\Debug" 
    ["mscorlib"; "System.Core"; "System"; "System.Xml"; "FSharp.Core"]