Connect to EventStore Cluster

EventStoreHelpers.fs

module EventStoreHelpers = 

    open System
    open System.Net
    open EventStore.ClientAPI

    let inline private (!>) (x:^a) : ^b = ((^a or ^b) : (static member op_Implicit : ^a -> ^b) x)

    let private dnsLookup (host : string) = 
        let hostEntry = Dns.GetHostEntry(host)
        let nonLoopback =
            hostEntry.AddressList
            |> Seq.tryFind (fun a ->
                not (a = IPAddress.Loopback) &&
                not (a = IPAddress.IPv6Loopback) &&
                not a.IsIPv6LinkLocal)
        match nonLoopback with
        | Some ip -> ip
        | None -> IPAddress.Loopback

    let createClusterConnection (endpoints : string seq) username pass = 
        let credentials = new SystemData.UserCredentials(username, pass)

        let ipEndpoints = 
            endpoints
            |> Seq.map (fun ep ->
                let parts = ep.Split(':')
                let hostPart,portPart = parts.[0],parts.[1]
                let ip = dnsLookup hostPart
                let port = Int32.Parse(portPart)
                new IPEndPoint(ip, port))
            |> Seq.toArray

        let connSettings = 
            !> ConnectionSettings.Create()
                .SetDefaultUserCredentials(credentials)

        let clusterSettings = 
            !> ClusterSettings.Create()
                .DiscoverClusterViaGossipSeeds()
                .SetGossipSeedEndPoints(ipEndpoints)
        
        let conn = EventStoreConnection.Create(connSettings, clusterSettings)
        conn.ConnectAsync () |> ignore
        conn