Running Arquillian with Gradle 2.1 + Spring.io Dependency Management plugin: https://github.com/spring-gradle-plugins/dependency-management-plugin

build.gradle

plugins {
    id "io.spring.dependency-management" version "0.2.1.RELEASE"
}
apply plugin: "io.spring.dependency-management"
apply plugin: 'java'

repositories {
   mavenCentral()
   mavenLocal()
}

dependencyManagement {
   imports {
      mavenBom 'org.jboss.arquillian:arquillian-bom:1.1.5.Final'
   }
}

dependencies {
   testCompile 'org.jboss.arquillian.junit:arquillian-junit-container'
   testCompile 'junit:junit:4.+'

   testRuntime 'org.wildfly:wildfly-arquillian-container-remote:8.1.0.Final'
}

build_managed.gradle

plugins {
    id "io.spring.dependency-management" version "0.2.1.RELEASE"
}
apply plugin: "io.spring.dependency-management"
apply plugin: 'java'


repositories {
   mavenCentral()
   mavenLocal()
}

configurations {
  install
}
 
dependencyManagement {
   imports {
      mavenBom 'org.jboss.arquillian:arquillian-bom:1.1.5.Final'
      mavenBom 'org.jboss.spec:jboss-javaee-6.0:3.0.0.Final'
   }
}
 
dependencies {
   testCompile 'org.jboss.arquillian.junit:arquillian-junit-container'
   testCompile 'org.jboss.shrinkwrap.descriptors:shrinkwrap-descriptors-impl-javaee'

   testCompile 'org.jboss.spec.javax.servlet:jboss-servlet-api_3.0_spec'
   testCompile 'javax.enterprise:cdi-api'
   
   testRuntime 'org.wildfly:wildfly-arquillian-container-managed:8.1.0.Final'
 
   testCompile 'junit:junit:4.+'

   install 'org.wildfly:wildfly-dist:8.1.0.Final@zip'
}

test {
   systemProperty 'arq.container.wildfly.configuration.jbossHome', 'build/unpacked/dist/wildfly-8.1.0.Final'
   systemProperty 'arquillian.launch', 'wildfly'
}

task unzip(type: Copy) {
    def zipFile = configurations.install.singleFile
    def outputDir = file("${buildDir}/unpacked/dist")

    from zipTree(zipFile)
    into outputDir

    tasks.test.dependsOn unzip
}

build_wlp.gradle

plugins {
    id "io.spring.dependency-management" version "0.2.1.RELEASE"
}
apply plugin: "io.spring.dependency-management"
apply plugin: 'java'
 
repositories {
   mavenCentral()
   mavenLocal()
}

def jdkHome = System.getenv("JAVA_HOME")
 
dependencyManagement {
   imports {
      mavenBom 'org.jboss.arquillian:arquillian-bom:1.1.7.Final'
   }
}
 
dependencies {
   testCompile 'org.jboss.arquillian.junit:arquillian-junit-container'
   testCompile 'junit:junit:4.+'
 
   testRuntime 'org.jboss.arquillian.container:arquillian-wlp-managed-8.5:1.0.0.Beta2'
   testRuntime files("$jdkHome/lib/tools.jar")
}