roccat.nix

with import <nixpkgs> {};

let
  libgaminggear = stdenv.mkDerivation rec {
    name = "libgaminggear-${version}";
    version = "0.13.0";

    src = fetchurl {
      url = "mirror://sourceforge/libgaminggear/${name}.tar.bz2";
      sha256 = "08p2z5l0p1vajq4ikchi82xd7bjrijdkpi5s6mpky2sahf72m4gz";
    };

    outputs = [ "dev" "out" "bin" ];

    nativeBuildInputs = [ cmake pkgconfig gettext ];
    propagatedBuildInputs = [
      gtk2 libcanberra libnotify pcre sqlite xorg.libXdmcp xorg.libpthreadstubs
    ];

    enableParallelBuilding = true;

    cmakeFlags = [
      "-DINSTALL_CMAKE_MODULESDIR=lib/cmake"
      "-DINSTALL_PKGCONFIGDIR=lib/pkgconfig"
      "-DINSTALL_LIBDIR=lib"
    ];

    postFixup = ''
      moveToOutput bin "$bin"
    '';
  };

in stdenv.mkDerivation rec {
  name = "roccat-tools-${version}";
  version = "5.2.0";

  src = fetchurl {
    url = "mirror://sourceforge/roccat/${name}.tar.bz2";
    sha256 = "1m1m0179nnwadsg7yf1izbs1wkrcd37m4x93j2cry98x5i5fx86n";
  };

  postPatch = ''
    sed -i -re 's,/(etc/xdg),\1,' roccateventhandler/CMakeLists.txt

    sed -i -e '/roccat_profile_dir(void).*{/,/}/ {
      /return/c \
        return g_build_path("/", g_get_user_data_dir(), "roccat", NULL);
    }' libroccat/roccat_helper.c
  '';

  nativeBuildInputs = [ cmake pkgconfig gettext ];
  buildInputs = [ dbus dbus_glib libgaminggear libgudev lua ];

  enableParallelBuilding = true;

  cmakeFlags = [
    "-DUDEVDIR=\${out}/lib/udev/rules.d"
    "-DCMAKE_MODULE_PATH=${libgaminggear.dev}/lib/cmake"
    "-DWITH_LUA=${lua.luaversion}"
    "-DLIBDIR=lib"
  ];
}