Excel formula to validate Singapore NRICs and FIN numbers (case-insensitive)

excel_nric.txt

= IF(
     LEN([NRIC]) = 9,
     
     UPPER(RIGHT([NRIC])) = VLOOKUP(
                                    UPPER(LEFT([NRIC])),
                                    
                                    {"S", "J", "Z", "I", "H", "G", "F", "E", "D", "C", "B", "A";
                                     "T", "J", "Z", "I", "H", "G", "F", "E", "D", "C", "B", "A";
                                     "F", "X", "W", "U", "T", "R", "Q", "P", "N", "M", "L", "K";
                                     "G", "X", "W", "U", "T", "R", "Q", "P", "N", "M", "L", "K"},
                                    
                                    MOD(VLOOKUP(
                                                UPPER(LEFT([NRIC])),
                                                {"S", 0; "T", 4; "F", 0; "G", 4},
                                                2,
                                                FALSE
                                        ) + 
                                        SUM(VALUE(
                                                  MID([NRIC], {2, 3, 4, 5, 6, 7, 8}, 1)
                                            ) * {2, 7, 6, 5, 4, 3 ,2}
                                        ), 
                                        11
                                    ) + 2,
                                    
                                    FALSE
                            ),
                                
     FALSE
)