aur-folly-git.PKGBUILD

# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor: Joel Teichroeb <joel@teichroeb.net>
# Contributor: Jonas Heinrich <onny@project-insanity.org>

pkgname=folly-git
pkgver=2019.03.18.00.r19.g4fe39e0f
pkgrel=1
pkgdesc='Folly is an open-source C++ library developed and used at Facebook'
arch=(i686 x86_64)
url='https://github.com/facebook/folly'
license=(Apache)
conflicts=(folly)
provides=(folly)
replaces=(folly)
depends=(google-glog gflags double-conversion libevent boost-libs jemalloc xz lz4 zstd snappy)
makedepends=(git boost python2 gtest)
source=(
  git+https://github.com/facebook/folly.git
)
md5sums=('SKIP')

pkgver() {
  cd folly
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd folly/folly
  find -name '*.py' -exec sed -i 's|^#!/usr/bin/env python$|#!/usr/bin/env python2|' {} \;
}

build() {
  cd folly/folly
  cmake -G Ninja -DCMAKE_INSTALL_PREFIX="$pkgdir/usr" -DCMAKE_BUILD_TYPE=Release ..
  ninja
}

package() {
  cd folly/folly
  ninja install
}