Power Assert 2

assert.cr

require "compiler/crystal/syntax"

class AssertToSVisitor < Crystal::ToSVisitor
  getter locations = [] of Int32

  def visit_any(node)
    if node.class.name.ends_with? "Literal"
      @str << node.to_s
      return false
    end
    if (loc = node.location)
      @str << "(__" << locations.size << "=("
      locations << case node
      when Crystal::Call
        node.name_column_number
      else
        loc.column_number
      end
    end
    super
  end

  def end_visit_any(node)
    super
    @str << "))"
  end
end

src = ARGV[0].gsub('\n', ' ')
visitor = AssertToSVisitor.new(io = MemoryIO.new)
Crystal::Parser.parse(src).accept(visitor)

puts "unless #{io}"
puts "  puts " + src.inspect
visitor.locations.each_with_index do |loc, i|
  puts %{  puts "#{" " * (loc - 1)}^\#{__#{i}}"}
end
puts "end"
print "#" * 80

main.cr

macro assert(expr)
  {% puts o = run("./assert", expr) %}
  {{ o }}
end

foo = "foo"
assert %{foo.index('o') == 1 + 2}

output.txt

unless (__0=(((__1=((__2=(foo)).index('o')))) == ((__3=(1 + 2)))))
  puts "foo.index('o') == 1 + 2"
  puts "               ^#{__0}"
  puts "    ^#{__1}"
  puts "^#{__2}"
  puts "                    ^#{__3}"
end
################################################################################
foo.index('o') == 1 + 2
               ^false
    ^1
^foo
                    ^3