Braess

Braess.nlogo

patches-own[delay base_delay road_type last_here]
turtles-own[birth_tick ticks_here route]
globals[travel_time top bottom middle spawn_time middle_prev avg cars_spawned dynamic_roads top_prob bottom_prob middle_prob]


to setup
  clear-all
  setup-roads
  reset-ticks
end


to go
  check_middle
  do_spawning_stuff
  ask turtles [do_turtle_stuff]
  ask dynamic_roads [do_dynamic_road_stuff]
  tick
end


to do_turtle_stuff
  ifelse ticks_here > delay
  [
    set last_here ticks
    move-to patch-ahead 1
    set ticks_here 1
  ]
  [set ticks_here ticks_here + 1]
  if patch-here = patch 22 22 and route = 0 [facexy 22 -22]
  if patch-here = patch 22 22 and route = 2 [facexy 0 0]
  if patch-here = patch -22 -22 [facexy 22 -22]
  if patch-here = patch 22 -22
  [
    set travel_time (ticks - birth_tick) / 2250
    ifelse avg = 0 [set avg travel_time][set avg ((19 * avg + travel_time) / 20)]
    ifelse route = 0
    [
      ifelse top = 0 [set top travel_time][set top ((travel_time) + ((smoothing - 1) * top)) / smoothing]
    ]
    [
      ifelse route = 1
      [
        ifelse bottom = 0 [set bottom travel_time][set bottom ((travel_time) + ((smoothing - 1) * bottom)) / smoothing]
      ]
      [
        ifelse middle = 0 [set middle travel_time][set middle ((travel_time) + ((smoothing - 1) * middle)) / smoothing]
      ]
    ]
    die
  ]
end


to do_spawning_stuff
  ifelse spawn_time > (1250 / spawn_rate) [
    ask patch -22 22 [
      sprout 1 [
        set cars_spawned cars_spawned + 1
        set color one-of [99]
        set birth_tick ticks
        set ticks_here 1
        set route new_route
        ifelse route = 0  or route = 2 [facexy 22 22][facexy -22 -22]
        set size 3.5
        set shape one-of ["car" "truck"]
      ]
    ]
    set spawn_time 0
  ]
  [set spawn_time spawn_time + 1]
end


to do_dynamic_road_stuff
  ifelse last_here = 0 [set delay base_delay / 2]
  [set delay floor(((1250 / spawn_rate)/(ticks - last_here + 1)) * base_delay)]
    ;if delay > base_delay [set delay base_delay]
  let g 255 + floor(255 * (0.5 - (delay / base_delay)))
  if g < 127 [set g 127]
  if g > 255 [set g 255]
  set pcolor (list 255 g 0)
end


to check_middle
  if middle_on != middle_prev
  [
    ifelse middle_on
    [
      ask patches with [pxcor = pycor + 1 or pxcor = pycor - 1 or pxcor = pycor - 2 or pxcor = pycor + 2 and pycor < 21 and pxcor < 21 and pxcor > -21 and pycor > -21] [set pcolor 5 set delay 0]
      ask patches with [pxcor = pycor and pycor > -21 and pycor < 21 and pxcor > -21 and pxcor < 21][set pcolor 9.9 set delay 0]
      set middle_prev middle_on
    ]
    [
      ifelse count turtles with [route = 2] = 0
      [
        ask patches with [pycor = pxcor or pxcor = pycor + 1 or pxcor = pycor - 1 or pxcor = pycor - 2 or pxcor = pycor + 2 and pycor < 21 and pxcor < 21 and pxcor > -21 and pycor > -21] [set pcolor 2 set delay 0]
        set middle_prev middle_on
      ]
      []
    ]

  ]
end


to setup-roads
  ask patches [
    let g random 16 + 96
    let c (list 0 g 0)
    set pcolor c
  ]

  ask patch -22 22 [set pcolor green set delay 50]
  ask patch 22 -22 [set pcolor red set delay 50]
  ask patch -22 -22 [set pcolor blue set delay 50]
  ask patch 22 22 [set pcolor blue set delay 50]
  ask patches with [pycor = 22 and pxcor > -22 and pxcor < 22] [set pcolor yellow set delay 25 set road_type 1 set base_delay 50]
  ask patches with [pxcor = 22 and pycor > -22 and pycor < 22] [set pcolor orange set delay 50]
  ask patches with [pxcor = -22 and pycor > -22 and pycor < 22] [set pcolor orange set delay 50]
  ask patches with [pycor = -22 and pxcor > -22 and pxcor < 22] [set pcolor yellow set delay 25 set road_type 1 set base_delay 50]
  set middle_prev middle_on
  ifelse middle_on
  [
    ask patches with [pycor = pxcor or pxcor = pycor + 1 or pxcor = pycor - 1 or pxcor = pycor - 2 or pxcor = pycor + 2 and pycor < 21 and pxcor < 21 and pxcor > -21 and pycor > -21] [set pcolor 5 set delay 0]
    ask patches with [pxcor = pycor and pycor > -21 and pycor < 21 and pxcor > -21 and pxcor < 21][set pcolor 9.9 set delay 0]
  ]
  [ask patches with [pycor = pxcor or pxcor = pycor + 1 or pxcor = pycor - 1 or pxcor = pycor - 2 or pxcor = pycor + 2 and pycor < 21 and pxcor < 21 and pxcor > -21 and pycor > -21] [set pcolor 2 set delay 0]]
  ask patches with [(pxcor = -21 or pxcor = 21) and pycor < 22 and pycor > -22] [set pcolor 5 set delay 0]
  ask patches with [(pycor = -21 or pycor = 21) and pxcor < 22 and pxcor > -22] [set pcolor 5 set delay 0]
  ask patches with [(pxcor = -23 or pxcor = 23) and pycor < 24 and pycor > -24] [set pcolor 5 set delay 0]
  ask patches with [(pycor = -23 or pycor = 23) and pxcor < 24 and pxcor > -24] [set pcolor 5 set delay 0]
  set dynamic_roads patches with [road_type = 1]
end

to-report new_route
 ifelse Mode = "Optimal" [report optimal-route]
        [
          ifelse Mode = "Worst" [report worst-route]
          [
            ifelse Mode = "Best Known /w Random Deviation" [report best-random-route]
            [
              ifelse Mode = "Empirical Analytical" [report analytical-route]
              [
                  ifelse Mode = "Probabilistic Greedy" [report probabalistic_greedy_route]
                  [
                    report 0
                  ]
              ]
            ]
          ]
        ]
end


to-report worst-route
  ifelse middle_on [report 2][report 0]
end


to-report optimal-route
  ifelse cars_spawned mod 2 = 0 [report 0][report 1]
end


to-report analytical-route
  ifelse middle_on
  [
    ifelse count other turtles = 0 [report random 3]
    [
      let top_score (count other turtles with [route = 0 or route = 2] / count other turtles) * 1 + 1
      let bottom_score (count other turtles with [route = 1 or route = 2] / count other turtles) * 1 + 1
      let middle_score (count other turtles with [route = 2] / count other turtles) * 2
      ifelse top_score < bottom_score and top_score < middle_score [report 0][ifelse bottom_score < middle_score and bottom_score < top_score [report 1][ifelse top_score = bottom_score and middle_score = top_score[report random 3][report 2]]]
    ]
  ]
  [
    ifelse count other turtles = 0 [report random 2]
    [
      let top_score (count other turtles with [route = 0] / count other turtles) * 1 + 1
      let bottom_score (count other turtles with [route = 1] / count other turtles) * 1 + 1
      ifelse top_score < bottom_score [report 0][report 1]
    ]
  ]
end


to-report best-random-route
  ifelse middle_on
  [
    ifelse middle = 0 or top = 0 or bottom = 0 [report random 3]
    [
      ifelse random 100 < 100 - Randomness [ifelse middle < top and middle < bottom [report 2][ifelse top < middle and top < bottom [report 0][report 1]]][report random 3]
    ]
  ]
  [
    ifelse top = 0 or bottom = 0 [report random 2]
    [
      ifelse random 100 < 100 - Randomness [ifelse top < bottom [report 0][report 1]] [report random 2]
    ]
  ]
end


to-report probabalistic_greedy_route
  ifelse middle_on
  [
    ifelse middle = 0 or top = 0 or bottom = 0 [report random 3]
    [

      let t_dif (2 - top)
      if t_dif < 0 [set t_dif 0]
      set t_dif t_dif ^ (Randomness / 10)

      let b_dif (2 - bottom)
      if b_dif < 0 [set b_dif 0]
      set b_dif b_dif ^ (Randomness / 10)

      let m_dif (2 - middle)
      if  m_dif < 0 [set m_dif 0]
      set m_dif m_dif ^ (Randomness / 10)

      let sigma1 t_dif / (t_dif + b_dif + m_dif)
      let sigma2 b_dif / (t_dif + b_dif + m_dif)
      set top_prob sigma1
      set bottom_prob sigma2
      set middle_prob 1 - sigma1 - sigma2
      let split1 1000 * sigma1
      let split2 1000 * (sigma1 + sigma2)
      let rand random 1000
      ifelse rand < split1 [report 0][ifelse rand < split2 [report 1][report 2]]
    ]
  ]
  [
    ifelse top = 0 or bottom = 0 [report random 2]
    [
      let t_dif (2 - top) ^ (Randomness / 10)
      let b_dif (2 - bottom) ^ (Randomness / 10)
      let sigma t_dif / (t_dif + b_dif)
      set top_prob sigma
      set bottom_prob 1 - sigma
      let split 1000 * sigma
      ifelse random 1000 < split [report 0][report 1]
    ]
  ]
end
@#$#@#$#@
GRAPHICS-WINDOW
205
10
850
656
-1
-1
13.0
1
10
1
1
1
0
0
0
1
-24
24
-24
24
0
0
1
ticks
30.0

BUTTON
99
39
162
72
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
99
78
162
111
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
8
182
194
215
spawn_rate
spawn_rate
1
10
10.0
1
1
NIL
HORIZONTAL

PLOT
860
10
1536
465
Travel Time
NIL
NIL
0.0
10.0
0.0
2.0
true
true
"" ""
PENS
"Actual Time" 1.0 1 -7500403 true "" "plot travel_time"
"Top" 1.0 0 -2674135 true "" "plot top"
"Bottom" 1.0 0 -14070903 true "" "plot bottom"
"Middle" 1.0 0 -13840069 true "" "plot middle"
"Smoothed Average" 1.0 2 -8990512 true "" "plot avg"

SWITCH
8
229
110
262
middle_on
middle_on
0
1
-1000

SLIDER
8
275
194
308
smoothing
smoothing
1
10
10.0
1
1
NIL
HORIZONTAL

CHOOSER
8
322
197
367
Mode
Mode
"Optimal" "Best Known /w Random Deviation" "Empirical Analytical" "Probabilistic Greedy" "Worst"
3

SLIDER
9
380
198
413
Randomness
Randomness
0
100
16.0
1
1
NIL
HORIZONTAL

PLOT
859
474
1059
624
Routes Taken
NIL
Number of Cars
0.0
3.0
0.0
10.0
true
true
"" ""
PENS
"Top" 1.0 1 -2674135 true "" "clear-plot plotxy 0 count turtles with [route = 0]"
"Bottom" 1.0 1 -13345367 true "" "plotxy 1 count turtles with [route = 1]"
"Middle" 1.0 1 -13840069 true "" "plotxy 2 count turtles with [route = 2]"

PLOT
1072
474
1272
624
Probabilities
NIL
NIL
0.0
3.0
0.0
1.0
true
true
"" ""
PENS
"Top" 1.0 1 -2674135 true "" "clear-plot plotxy 0 top_prob"
"Bottom" 1.0 1 -13345367 true "" "plotxy 1 bottom_prob"
"Middle" 1.0 1 -13840069 true "" "plotxy 2 middle_prob"

@#$#@#$#@
# WHAT IS IT?

This is an agent-based model intended to demonstrate a phenomena from game theory (a subfield of economics) called Braess' paradox.

Braess' paradox is a counter-intuitive result that arises when analyzing speciffic graphs through a game theoretic lens. These graphs are usually taken to be representations of traffic networks, but Braess' paradox is actually a wide-ranging phenomenon that can be applied in many contexts outside of traffic networks. For simplicity however, we will interpret and represent these graphs only as traffic networks in this model. Given a graph of a particular traffic network we can determine a stable set of strategies (routes for commuting from one point to another) that agents (autonomous commuters in this case) will prefer to adopt over all other strategies. This is called a Nash equilibrium. The strategies adopted by the agents in the Nash equilibrium will lead to outcomes for the agents-in this case the amount of time it takes them to reach their destination. Since we assume that all the agents are the same in this scenario, their outcomes will all be the same, and so, the global outcome of the system will be the same as the agents' individual outcomes. The paradoxical aspect of Braess' paradox arises when an additional route is added to the traffic network that has a very low time cost. When this is done the Nash equilibrium can be changed to one that has both worse individual and global outcomes (travel times.) In short, we can open more roads and actually make traffic worse. (Braess et al., 2005) 


# HOW IT WORKS

The turtles (commuters) in this model will come into existence at the starting node of the traffic networking in the upper left corner. The turtles are represented graphically as car or trucks, but this is just for visual effect. All turtles adhere to the same behavioral rules. Some heuristic or algorithm is used by the agents to determine the path it will take through the network before it begins. The agent then moves through the model, one road square (patch) at a time and remains in that patch for a number of ticks before moving on to the next patch. When the agent reaches the ending node it reports the path it took through the network and also the total number of ticks it spent in transit. This information is saved by the model and used to generate a "traffic report" which new agents can then incorporate into their algorithm or heuristic to choose the route they take. The patches in this model represent roads. There are two types of road patches: static cost roads and dynamic cost roads. Static cost roads require the car to stay in that patch for a fixed amount of time before moving on. Dynamic cost roads require the car to stay in that patch for an amount of time that is based on the number of ticks since the last turtle occupied that patch, thus simulating congestion.There is also a switch in the model which allows a middle path of road patches of near zero cost to be opened or closed. As mentioned above when agents reach the end of the traffic network they report their route choice and the time taken in ticks. There are three possible routes and the time re-ports are taken and used to determine three global variables corresponding to each route. The can be thought of as traffic reports. This information is then used by future agents in deciding which route to take. In this model we have included a user adjustable parameter called smoothing referred to here as s. If s is set to 1 only the last reported time for a given route will be used by agents in their decisions. Otherwise the formula for the information that the agents have access to is a psuedo-average that weights less recent reports lower. This parameter is added so that agents can be made to take into account information about more than just the previous agent to complete a given route when making their decisions about which route they would prefer to take. Adjusting the smoothing parameter in the model can sometimes be useful in eradicating wild oscillations in agent route preferences.

## Algorithms and Heuristics

What follow are descriptions of the different modes by which agents in the model will determine the route they take through the traffic network. These modes can be set before the model is started but they can also be changed during model execution. There is also (as previously mentioned) a user switch which will determine if the middle path is open or closed. All of the modes will function appropriately with the middle open or closed.

* __Optimal:__ The Optimal Mode forces all agents to take the path that is known to have the best outcome globally. This always entails the agents alternating between taking the top and bottom route.  




* __Worst:__ The Worst Mode forces the agents to take the path that is globally worst in the network. In the case where the middle road is not open Worst Mode will force all the cars to take the top route. In the case where the middle route is open Worst Mode will force the cars to take the middle route. Neither Optimal Mode nor Worst Mode are of much experimental interest, but rather, just serve to set-up a baseline for performance.  



* __Best Known with Random Deviation:__ When this mode is active the cars will choose the route with the lowest current average time or deviate to a random route with some probability defined by the value of the probability parameter in the model divided by one-hundred.  



* __Empirical Analytical:__ In this mode the cars have knowledge of the current number of cars on the road and which routes they are taking. They use this information to analytically compute which route will be best for them to take and then take that route.  



* __Probabilistic Greedy:__ In this mode the agents will choose routes with a probability that is proportional to the performance of the given route. Here the randomness parameter is used to determine how heavily the probability is distributed into the better routes. A randomness settings of zero will make no route more likely than any other regardless of the performance of the route. A randomness settings of one-hundred will make it overwhelmingly likely that the cars will only take the current best route.  


# HOW TO USE IT

The __SETUP__ button initializes the model.

The __GO__ button runs the model.

The __spawn_rate__ slider determines how often new vehicles appear at the starting node. The road congestion is determined in proportion to the __spawn_rate__ however, so __spawn_rate__ will not affect travel time at all.

The __middle_on__ switch determines whether or not cars can pass down the middle road. If the __middle_on__ switch is turned off all vehicles currently taking the middle road will finish their trip before the middle road is disabled.

The __Mode__ selection panel selects between the algorithms and heuristics described above for determining which route the vehicles choose.

The __randomness__ and __smoothing__ parameters affect different algorithms and heuristics differently. They way in which they do so is also described above.

The __Routes Taken__ graph shows a histogram of which routes the currently active vehicles are taking. (Vehicles choose their route as soon as the come into existence.)

The __Probabilities__ graph shows a histogram of the probabilities with which new vehicles will choose a given route when a mode is selected that is probabilistic. 

The main __Travel Time__ graph displays a variety of different information. The filled grey area is the actual amount of time (in ticks) it takes an individual vehicle to travel from the starting node to the ending node. The light blue line is a smoothed average of the travel time of all the vehicles to have traveled the network with more recent vehicles weighted more strongly.

The Blue, Red, and Green lines all represent the average travel time of all vehicles to have completed the corresponding routes. The average is affected by the smoothing parameter which determines how strongly weighted more recent vehicles compared to less recent vehicles.
 

# THINGS TO TRY AND THINGS TO NOTICE

To observe Braess' Paradox, try using different algorithms and heuristics and observe the average travel times when the middle route is closed and when the middle route is open. Try adjusting the smoothing parameter and notice how the stability of which route vehicles take varies. The best and worst average travel times can be demonstrated by selecting the optimal and worst modes. These can be used as baselines to compare the performance of the other algorithms and heuristics. 


# EXTENDING THE MODEL

New algorithms for determining which routes the vehicles take could easily be added to this model. Also the traffic network could be changed or extended to have different topology.


# CREDITS AND REFERENCES

Braess, D., Nagurney, A., and Wakolbinger, T.(2005). On a paradox of traffic planning. 
   _Transportation science, 39(4):446–450._

Fudenberg, D. and Tirole, J.(1991). Game theory, 1991.
   _Cambridge, Massachusetts, 393(12):80._
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
15
Circle -1 true true 203 65 88
Circle -1 true true 70 65 162
Circle -1 true true 150 105 120
Polygon -7500403 true false 218 120 240 165 255 165 278 120
Circle -7500403 true false 214 72 67
Rectangle -1 true true 164 223 179 298
Polygon -1 true true 45 285 30 285 30 240 15 195 45 210
Circle -1 true true 3 83 150
Rectangle -1 true true 65 221 80 296
Polygon -1 true true 195 285 210 285 210 240 240 210 195 210
Polygon -7500403 true false 276 85 285 105 302 99 294 83
Polygon -7500403 true false 219 85 210 105 193 99 201 83

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

wolf
false
0
Polygon -16777216 true false 253 133 245 131 245 133
Polygon -7500403 true true 2 194 13 197 30 191 38 193 38 205 20 226 20 257 27 265 38 266 40 260 31 253 31 230 60 206 68 198 75 209 66 228 65 243 82 261 84 268 100 267 103 261 77 239 79 231 100 207 98 196 119 201 143 202 160 195 166 210 172 213 173 238 167 251 160 248 154 265 169 264 178 247 186 240 198 260 200 271 217 271 219 262 207 258 195 230 192 198 210 184 227 164 242 144 259 145 284 151 277 141 293 140 299 134 297 127 273 119 270 105
Polygon -7500403 true true -1 195 14 180 36 166 40 153 53 140 82 131 134 133 159 126 188 115 227 108 236 102 238 98 268 86 269 92 281 87 269 103 269 113

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 6.0.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
0
@#$#@#$#@