TextExpander Applescript to turn Methods into Declarations (from Clipboard contents)

gistfile1.scpt

set clipText to (the clipboard as string)
set theItems to paragraphs of clipText
set ret to ""

on replaceText(find, replace, subject)
    set prevTIDs to text item delimiters of AppleScript
    set text item delimiters of AppleScript to find
    set subject to text items of subject
 
    set text item delimiters of AppleScript to replace
    set subject to "" & subject
    set text item delimiters of AppleScript to prevTIDs
 
    return subject
end replaceText

on makeFuncDec(subject)
    set ret to "" 
    if subject ends with " {" then
        set ret to replaceText(" {", ";\n", subject)
    else if subject ends with "{" then
        set ret to replaceText("{", ";\n", subject)
    else
        set ret to subject & ";\n"
    end if

    return ret
end makeFuncDec

repeat with theLine in theItems
    set p to theLine as string

    if p starts with "- (" or p starts with "-(" or p starts with "+ (" or p starts with "+(" then
        set ret to ret & makeFuncDec(p)
    end if

end repeat

return ret

Setup

Make a TextExpander AppleScript snippet with this as the content, set the abbreviation (I'll assume you made it ;fdecs for the purpose of this ReadMe).

Usage

Copy your implementation to your clipboard

E.G:

- (void)handleLongPress:(UILongPressGestureRecognizer*)gesture {
    if (gesture.state == UIGestureRecognizerStateRecognized) {
        // DO SOMETHING
    }
}
- (void)didPressDone:(id)sender {
    // DO SOMETHING
}
- (void)didPressNext:(id)sender {
    // DO SOMETHING
}
- (void)didPressPrevious:(id)sender {
    // DO SOMETHING
}

Go you your header file and type your abbreviation, and it will output the declarations for the methods

E.G.

- (void)handleLongPress:(UILongPressGestureRecognizer*)gesture;
- (void)didPressDone:(id)sender;
- (void)didPressNext:(id)sender;
- (void)didPressPrevious:(id)sender;