NAPS2 on NixOS from Debian package

naps2.nix

{ autoPatchelfHook
, curl
, dotnet-runtime
, dotnet-sdk
, dpkg
, fetchurl
, gtk3
, icu
, krb5
, lib
, libnotify
, mesa
, nspr
, nss
, sane-backends
, stdenv
, wrapGAppsHook
, patchelf
}:

stdenv.mkDerivation rec {
  pname = "naps2";
  version = "7.1.1";

  src = fetchurl {
    url = "https://github.com/cyanfish/naps2/releases/download/v${version}/naps2-${version}-linux-x64.deb";
    hash = "sha256-LD5LN0d1X8a3/2FX37qUDwPB0KnVBaV/glcnntzWMq8=";
  };

  nativeBuildInputs = [ autoPatchelfHook dpkg wrapGAppsHook patchelf ];

  buildInputs = [
    curl
    dotnet-sdk
    gtk3
    krb5
    mesa
    nspr
    nss
  ];

  runtimeDependencies = [
    (lib.getLib dotnet-runtime)
    (lib.getLib gtk3)
    (lib.getLib icu)
    (lib.getLib sane-backends)
    (lib.getLib libnotify)
    ];

  installPhase = ''
    runHook preInstall
    mkdir -p "$out/bin"
    cp -R usr $out
    ln -s "$out/usr/lib/naps2/naps2" "$out/bin/naps2"
    chmod -R g-w "$out"
    runHook postInstall
  '';

  postInstall = ''
    patchelf --set-rpath "${dotnet-sdk}/shared/Microsoft.NETCore.App/6.0.22:$out/usr/lib/naps2" "$out/usr/lib/naps2/libsos.so"
  '';

  meta = with lib; {
    description = "Scan documents to PDF and more, as simply as possible.";
    homepage = "https://www.usenaps2.com";
    license = licenses.gpl2;
    maintainers = with maintainers; [ cyanfish ];
    platforms = [ "x86_64-linux" ];
  };
}