Infinite scroll with Ember.js and Ruby on Rails - These Ember Mixins are used by my Rails template for setting up infinite scrolling with Ember.js and Ruby on Rails. The template is located here https://github.com/bazzel/rails-templates/blob/master/ember-infinite-scroll.rb

ember-infinite-scroll.js.coffee

InfiniteScroll =
  ControllerMixin: Ember.Mixin.create(
    hasMore: (->
      @meta('page') < @meta('total_pages')
    ).property('@each')

    meta: (key) ->
      @store.metadataFor(@_type())[key]

    loadMore: ->
      if @get('hasMore')
        @set('isLoading', yes)
        @store.find(@_type(),
          page: @meta('page') + 1
        ).then(=>
          @set('isLoading', no)
        )

    _type: ->
      fullClassName = @get('model').type.toString()
      className = fullClassName.replace(/.*\./, "")
      className.underscore()
  ),

  ViewMixin: Ember.Mixin.create(
    startObserveScrolling: (->
      $(window).bind('scroll', => @didScroll())
    ).on('didInsertElement')

    stopObserveScrolling: (->
      $(window).unbind('scroll')
    ).on('willDestroyElement')

    didScroll: ->
      if @isScrolledToBottom()
        @get('controller').loadMore()

    isScrolledToBottom: ->
      distanceToTop = $(document).height() - $(window).height()
      top           = $(document).scrollTop()

      top is distanceToTop
  )

window.InfiniteScroll = InfiniteScroll