Autocode metaprogramming POC in Crystal

README.md

Compiling

crystal build main.cr

will change Settings declaration in main.cr from

class Settings
  auto
end

to

class Settings
  auto
  property baz
  property bar
  property foo
end

Yet the program needs to be compiled twice to get the property code expanded.

autocode.cr

macro auto(file = __FILE__, line = __LINE__)
  {% metadata_file = file + "." + @type.name.stringify + ".auto" %}
  {{ run("./autoprepare", {{metadata_file}}) }}
  macro method_missing(name, args, block)
    \{{ run("./autowritter", {{file}}, {{line}}, @type.name, name, {{metadata_file}}) }}
    nil
  end
end

autoprepare.cr

File.write(ARGV[0], "")

autowritter.cr

file, loc, type_name, prop, metadata_file = ARGV[0], ARGV[1].to_i, ARGV[2], ARGV[3], ARGV[4]

prop = prop[0..-2] if prop[-1] == '='

File.each_line(metadata_file) do |other_prop|
  exit if other_prop.strip == prop
end

File.open(metadata_file, "a") do |metadata|
  metadata.print("#{prop}\n")
end

content = File.read(file)
File.open(file, "w") do |f|
  content.each_line do |line|
    f.print(line)

    if loc == 1
      prefix = /^\s*/.match(line)
      f.print("#{prefix.not_nil![0]}property #{prop}\n")
    end

    loc -= 1
  end
end

main.cr

require "./autocode"

class Settings
  auto
end

s = Settings.new
s.foo = 1
s.bar
s.baz
puts s.foo