squares n rods

squaresRods.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

float c01(float g) {
  return constrain(g, 0, 1);
}

void draw() {
  if (recording) {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  } else if (preview) {
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    t = (millis()/(20.0*numFrames))%1;
    draw_();
  } else {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 140;        
float shutterAngle = .6;

boolean recording = true, 
  preview = true;

void setup() {
  size(750, 750, P3D);
  smooth(8);  
  rectMode(CENTER);
  pixelDensity(recording ? 1 : 2);
  result = new int[width*height][3];
  fill(32);
  noStroke();
  ortho();
}

float x, y, z, tt;
int N = 12;
float ii;
color c1 = #140249, c2 = #8bd1cd;

void draw_() {
  stroke(c1);
  fill(c2);
  strokeWeight(3);
  background(c2);
  push();
  translate(width/2, height/2);
  push();
  rotate(PI*.07);
  for (int i=-4; i<5; i++) {
    ii = i + t;
    push();
    translate(100*ii, 0);
    rect(0, 0, 32, height*2);

    for (int j=-8; j<9; j++) {

      tt = (t + 100 - .125*j - .05*ii)%1;

      push();
      translate(40*sin(TWO_PI*tt), 80*j, 30*cos(TWO_PI*tt));
      rotate(PI*tt);
      rect(0, 0, 30, 30);
      pop();
    }

    pop();
  }
  pop();

  push();
  translate(0, 0, 100);
  noFill();
  rect(0, 0, 450, 450);
  pop();

  push();
  translate(0, 0, 99);
  noStroke();
  for (int i=0; i<4; i++) {
    push();
    rotate(HALF_PI*i);
    rect(0, -450, 900, 450);
    pop();
  }
  pop();



  pop();
}