waves

waves.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 200;        
float shutterAngle = .6;

boolean recording = false;

void setup() {
  size(750, 650, P3D);
  smooth(8);
  strokeWeight(2.5);
  result = new int[width*height][3];
  rectMode(CENTER);
  fill(32);
  noStroke();
}

float x, y, z, tt;
int n = 600, N = 20;
float q, am;

void thing(float y_, int f) {
  stroke(250);
  noFill();
  beginShape();
  for (int i=0; i<n; i++) {
    q = i/float(n-1);
    x = lerp(-width/2-12, width/2+12, q);
    y = y_;
    am = map(cos(TWO_PI*t - 0.007*dist(x,y,0,0)),1,-1,0,exp(-.002*dist(x,y,0,0)));
    x += ease(sq(am),3)*10*sin(2*TWO_PI*N*q);
    y += ease(1-sq(1-am),3)*17*cos(TWO_PI*N*q);
    vertex(x, y);
  }
  endShape();
}
void draw_() {
  background(20); 
  push();
  translate(width/2, height/2);
  scale(1.1);
  for (int i=-9; i<=9; i++)
    thing(40*i, i);
  pop();
}

gif: https://twitter.com/beesandbombs/status/879837200879411202