sphere lights

sphereLights.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

float c01(float g) {
  return constrain(g, 0, 1);
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 280;        
float shutterAngle = .5;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  pixelDensity(recording ? 1 : 2);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  fill(32);
  noStroke();
  sphereDetail(8);
}

float x, y, z, tt, r = 240;
float X, Y, Z, R;
int N = 400;
float age;
float rotSpeed;
float x_, y_, z_;

void light() {
  rotSpeed = random(-1, -.2);
  
  X = randomGaussian();
  Y = randomGaussian();
  Z = randomGaussian();
  R = dist(0, 0, 0, X, Y, Z);
  x_ = X*r/R;
  y_ = Y*r/R;
  z_ = Z*r/R;

  age = (t + 1000 - .0016*y + randomGaussian()*.18) % 1;
  age = c01(1.5*age);

  x = x_*cos(rotSpeed*age) + z_*sin(rotSpeed*age);
  y = y_;
  z = z_*cos(rotSpeed*age) - x_*sin(rotSpeed*age);
  
  push();
  translate(x, y, z);
  fill(map(cos(TWO_PI*age), 1, -1, 0, map(modelZ(x, y, z), -r, r, 100, 255)));
  sphere(map(cos(TWO_PI*age), 1, -1, 0, 3.5));
  pop();
}

void draw_() {
  background(0); 
  push();
  translate(width/2, height/2);
  randomSeed(1);
  for (int i=0; i<N; i++)
    light();
  pop();
}