triangle sweep

triangleSweep.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("t###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 220;        
float shutterAngle = .8;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  smooth(8);
  strokeWeight(1.2);
  result = new int[width*height][3];
  rectMode(CENTER);
  stroke(50);
  noFill();
}

float x, y, z, tt;
int N = 96, speed = 8;
float rad = 275;
int start;

float qq, x1, y1, x2, y2;
void oneLine(float q) {
  qq = (3*q)%1;
  x1 = lerp(-rad*mn, 0, qq);
  x2 = lerp(0, rad*mn, qq);
  y1 = lerp(rad/2, -rad, qq);
  y2 = lerp(-rad, rad/2, qq);
  push();
  rotate(TWO_PI*int(3*q)/3.0);
  line(x1, y1, x2, y2);
  pop();
}


void draw_() {
  start = int((N-speed)*t);
  background(247); 
  push();
  translate(width/2, height/2 + 50);
  triangle(0,-rad,-rad*mn,rad/2,rad*mn,rad/2);
  for (int i=start; i<start+N/3; i++)
    oneLine((i+speed*t)/float(N));
  pop();
}

gif: https://twitter.com/beesandbombs/status/881857295008882689