hexes / tris

hexesTris.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

float c01(float g) {
  return constrain(g, 0, 1);
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 180;        
float shutterAngle = .6;

boolean recording = false;

void setup() {
  size(750, 750, P2D);
  strokeJoin(CORNER);
  pixelDensity(recording ? 1 : 2);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  stroke(255);
  noFill();
  strokeWeight(3);
  colorMode(HSB);
  blendMode(ADD);
}

float x, y, z, tt;
int N = 12;
float r = 95;
float easing  = 3.5;

void hexx() {
  beginShape();
  for (int i=0; i<6; i++) {
    vertex(r*cos(TWO_PI*i/6), r*sin(TWO_PI*i/6));
  }
  endShape(CLOSE);
}

void halfHex() {
  beginShape();
  for (int i=-1; i<4; i++) {
    vertex(r*cos(TWO_PI*i/6), r*sin(TWO_PI*i/6));
  }
  endShape();
}

float tr = r/(2*mn);
void tri() {
  triangle(0, -tr, -tr*mn, tr/2, tr*mn, tr/2);
}

void shapes(float ti){
  ti %= 1;
  if (3*ti <= 1) {
    q = 3*ti;
    hexx();
    for (int i=0; i<6; i++) {
      push();
      rotate(TWO_PI*i/6);
      push();
      translate(-r/2, r*mn);
      rotate(TWO_PI*ease(q,easing)/6);
      translate(r/2, r*mn);
      hexx();
      pop();
      pop();
    }
  }
  
   else if (3*ti <= 2) {
    q = 3*ti - 1;
    for (int i=0; i<6; i++) {
      push();
      rotate(TWO_PI*i/6);
      push();
      translate(-r/2, r*mn);
      rotate(TWO_PI/6);
      translate(r/2, r*mn);
      halfHex();
      pop();
      
      push();
      translate(0,-tr*2);
      rotate(TWO_PI*ease(q,easing)/3);
      tri();
      pop();
      
      pop();
    }
  }
  
  else {
    q = 3*ti-2;
    hexx();
    for (int i=0; i<6; i++) {
      push();
      rotate(TWO_PI*i/6);
      push();
      translate(-r/2, r*mn);
      rotate(TWO_PI*(1+ease(q,easing))/6);
      translate(r/2, r*mn);
      hexx();
      pop();
      pop();
    }
  }
}

float q;

void draw_() {
  if(!recording)
    t = (millis()/(20.0*numFrames))%1;
  background(0);
  push();
  translate(width/2, height/2);

  for (int i=0; i<N; i++) {
    stroke(255.0*i/N, 240, 200);
    shapes(t+.02*i/N);
  }

  pop();
}