Skip to content

Instantly share code, notes, and snippets.

@beesandbombs
Created October 9, 2018 23:32
  • Star 4 You must be signed in to star a gist
  • Fork 0 You must be signed in to fork a gist
Star You must be signed in to star a gist
Save beesandbombs/c43878a201d2789f73a66d08b634ce99 to your computer and use it in GitHub Desktop.
squares & circles
int[][] result;
float t, c;
float ease(float p) {
return 3*p*p - 2*p*p*p;
}
float ease(float p, float g) {
if (p < 0.5)
return 0.5 * pow(2*p, g);
else
return 1 - 0.5 * pow(2*(1 - p), g);
}
float mn = .5*sqrt(3), ia = atan(sqrt(.5));
void push() {
pushMatrix();
pushStyle();
}
void pop() {
popStyle();
popMatrix();
}
float c01(float g) {
return constrain(g, 0, 1);
}
void draw() {
if (!recording) {
t = mouseX*1.0/width;
c = mouseY*1.0/height;
if (mousePressed)
println(c);
draw_();
} else {
for (int i=0; i<width*height; i++)
for (int a=0; a<3; a++)
result[i][a] = 0;
c = 0;
for (int sa=0; sa<samplesPerFrame; sa++) {
t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
draw_();
loadPixels();
for (int i=0; i<pixels.length; i++) {
result[i][0] += pixels[i] >> 16 & 0xff;
result[i][1] += pixels[i] >> 8 & 0xff;
result[i][2] += pixels[i] & 0xff;
}
}
loadPixels();
for (int i=0; i<pixels.length; i++)
pixels[i] = 0xff << 24 |
int(result[i][0]*1.0/samplesPerFrame) << 16 |
int(result[i][1]*1.0/samplesPerFrame) << 8 |
int(result[i][2]*1.0/samplesPerFrame);
updatePixels();
saveFrame("f###.gif");
if (frameCount==numFrames)
exit();
}
}
//////////////////////////////////////////////////////////////////////////////
int samplesPerFrame = 4;
int numFrames = 400;
float shutterAngle = 1;
boolean recording = false;
void setup() {
size(720, 720, P3D);
pixelDensity(recording ? 1 : 2);
smooth(8);
result = new int[width*height][3];
rectMode(CENTER);
noStroke();
}
float x, y, z, tt;
int N = 32;
float th, qq, R = 31, sp = 3*R;
void cap(float q) {
beginShape();
for (int i=0; i<N; i++) {
qq = i/float(N);
th = lerp(-QUARTER_PI, QUARTER_PI, qq);
x = R*(sin(th));
y = R*(cos(th)-cos(QUARTER_PI))*(1-q);
vertex(x, y);
}
for (int i=0; i<N; i++) {
qq = i/float(N);
th = lerp(-QUARTER_PI, QUARTER_PI, qq);
x = -R*(sin(th));
y = -R*(cos(th)-cos(QUARTER_PI))*q;
vertex(x, y);
}
endShape(CLOSE);
}
color RED = #c83131, BLUE = #1b3181;
float grow = 1.175;
void draw_() {
background(248, 240, 234);
push();
translate(width/2, height/2);
for (int a=-5; a<6; a++) {
for (int b=-5; b<6; b++) {
tt = map(cos(TWO_PI*t - 0.16*dist(a, b, 0, 0)), 1, -1, 0, 1);
tt = ease(tt, 3);
push();
translate(a*sp, b*sp);
fill((a+b)%2 == 0 ? RED : BLUE);
push();
if ((a+b)%2 == 0)
scale(pow(grow, tt));
else
scale(pow(grow, 1-tt));
rect(0, 0, R*sqrt(2), R*sqrt(2));
pop();
if ((a+b)%2 == 0) {
fill(lerpColor(RED, BLUE, ease(tt)));
for (int i=0; i<4; i++) {
push();
rotate(HALF_PI*i);
translate(0, R*cos(QUARTER_PI) + (sp-R*sqrt(2))*tt);
cap(tt);
pop();
}
}
pop();
}
}
pop();
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment