hue donut

hueDonut.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

float c01(float g) {
  return constrain(g, 0, 1);
}

void draw() {
  if (recording) {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.png");
    if (frameCount==numFrames)
      exit();
  } else if (preview) {
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    t = (millis()/(20.0*numFrames))%1;
    draw_();
  } else {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 144;        
float shutterAngle = .6;

boolean recording = false, 
  preview = true;

void setup() {
  size(750, 750, P3D);
  smooth(8);  
  result = new int[width*height][3];
  colorMode(HSB,1);
  noStroke();
}

float x, y, z, tt;
int nSides = 72, nCircs = 360;
float R = 180, r = 70;  // radii
PImage fr;
float hue, hueSpread = 0.3;
float th;
float chop = .7;  // can draw fewer because of overlap trick...

void hueCirc(float initHue){  
  beginShape();
  for(int i=0; i<nSides; i++){
    th = TWO_PI*i/nSides;
    x = r*cos(th);
    y = r*sin(th);
    hue = (initHue + map(y,r,-r,0,hueSpread)) %1;
    fill(hue,1,1);
    vertex(r*cos(th), r*sin(th));
  }
  endShape(CLOSE);
}

void draw_() {
  background(0);
  push();
  translate(width/2, height/2);
  for(int i=0; i<nCircs*chop; i++){
    push();
    translate(R*sin(TWO_PI*i/nCircs + PI), R*cos(TWO_PI*i/nCircs + PI));
    hueCirc(t);
    pop();
  }
  
  
  // now take care of that overlap!
  fr = get();
  for(int i=0; i<nCircs*chop; i++){
    push();
    translate(R*sin(TWO_PI*i/nCircs), R*cos(TWO_PI*i/nCircs));
    hueCirc(t);
    pop();
  }
  
  pop();
  
  copy(fr,0,0,width/2,height,0,0,width/2,height);
}