Skip to content

Instantly share code, notes, and snippets.

Embed
What would you like to do?
blurry hexes
int[][] result;
float t, c;
float ease(float p) {
return 3*p*p - 2*p*p*p;
}
float ease(float p, float g) {
if (p < 0.5)
return 0.5 * pow(2*p, g);
else
return 1 - 0.5 * pow(2*(1 - p), g);
}
float mn = .5*sqrt(3), ia = atan(sqrt(.5));
float c01(float g) {
return constrain(g, 0, 1);
}
void draw() {
if (recording) {
for (int i=0; i<width*height; i++)
for (int a=0; a<3; a++)
result[i][a] = 0;
c = 0;
for (int sa=0; sa<samplesPerFrame; sa++) {
t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
draw_();
loadPixels();
for (int i=0; i<pixels.length; i++) {
result[i][0] += pixels[i] >> 16 & 0xff;
result[i][1] += pixels[i] >> 8 & 0xff;
result[i][2] += pixels[i] & 0xff;
}
}
loadPixels();
for (int i=0; i<pixels.length; i++)
pixels[i] = 0xff << 24 |
int(result[i][0]*1.0/samplesPerFrame) << 16 |
int(result[i][1]*1.0/samplesPerFrame) << 8 |
int(result[i][2]*1.0/samplesPerFrame);
updatePixels();
saveFrame("f###.gif");
if (frameCount==numFrames)
exit();
} else if (preview) {
c = mouseY*1.0/height;
if (mousePressed)
println(c);
t = (millis()/(20.0*numFrames))%1;
draw_();
} else {
t = mouseX*1.0/width;
c = mouseY*1.0/height;
if (mousePressed)
println(c);
draw_();
}
}
//////////////////////////////////////////////////////////////////////////////
int samplesPerFrame = 64;
int numFrames = 180;
float shutterAngle = .5;
boolean recording = false,
preview = true;
void setup() {
size(800, 600, P3D);
smooth(8);
pixelDensity(recording ? 1 : 2);
result = new int[width*height][3];
noStroke();
blendMode(ADD);
colorMode(HSB, 1);
}
int nDots;
float qq;
float bx, by;
float d;
void blurryLine(float x1_, float y1_, float x2_, float y2_, float blurAmt) {
nDots = ceil(dist(x1_, y1_, x2_, y2_)*(1+5*sq(blurAmt)));
d = 6*(1*(1-blurAmt)+0*sq(1-blurAmt));
for (int i=0; i<nDots; i++) {
bx = map(i, 0, nDots, x1_, x2_);
by = map(i, 0, nDots, y1_, y2_);
bx += 13*blurAmt*randomGaussian();
by += 13*blurAmt*randomGaussian();
ellipse(bx, by, d, d);
}
}
void blurryHex(float x_, float y_, float r_, float blurAmt) {
for (int i=0; i<6; i++) {
blurryLine(x_ + r_*cos(TWO_PI*i/6), y_+r_*sin(TWO_PI*i/6),
x_ + r_*cos(TWO_PI*(i+1)/6), y_+r_*sin(TWO_PI*(i+1)/6),
blurAmt);
}
}
float x, y, z, tt;
int N = 12;
void draw_() {
background(0);
push();
translate(width/2, height/2);
for (int i=0; i<N; i++) {
fill((i/float(N)+.5)%1,.7,0.25);
blurryHex(160*cos(TWO_PI*t - PI*i/N), 0, 90, i*1.0/N);
}
pop();
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment