Firefox 123.0 X cursor issue

flake.nix

# reproduces the issue mentioned in https://github.com/NixOS/nixpkgs/pull/289987
{
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
  inputs.nixpkgs-good.url = "github:NixOS/nixpkgs/477c559e96e15e993a523173e9ea5ef6a04f6885";
  inputs.nixpkgs-bad.url = "github:NixOS/nixpkgs/a56230f51fe59a583b0ed7e688e7a1dc1802f4a3";

  outputs = { nixpkgs, nixpkgs-good, nixpkgs-bad, ... }:
  {
    nixosConfigurations.test = nixpkgs.lib.nixosSystem
    {
      system = "x86_64-linux";
      modules =
      [
        ({ pkgs, lib, ... }:
        {
          environment.systemPackages = with pkgs;
          [
            (pkgs.writeShellScriptBin "firefox-good"
            ''
              exec ${nixpkgs-good.legacyPackages.${pkgs.system}.firefox}/bin/firefox https://wikipedia.com
            '')
            (pkgs.writeShellScriptBin "firefox-bad"
            ''
              exec ${nixpkgs-bad.legacyPackages.${pkgs.system}.firefox}/bin/firefox https://wikipedia.com
            '')
          ];

          networking.useDHCP = lib.mkForce true;

          systemd.services."serial-getty@ttyS0" =
          {
            enable = true;
            wantedBy = [ "getty.target" ];
          };

          users.groups.user = {};
          users.users.user =
          {
            group = "user";
            hashedPassword = "";
            isNormalUser = true;
          };

          services =
          {
            getty.autologinUser = "root";
            resolved.extraConfig = lib.mkForce "";
            xserver =
            {
              enable = true;
              displayManager =
              {
                autoLogin.enable = true;
                autoLogin.user = "user";
              };
              desktopManager =
              {
                xfce.enable = true;
                xfce.enableScreensaver = false;
              };
            };
          };

          hardware.opengl = { enable = true; driSupport = true; };
        })
      ];
    };
  };
}