xmas-lights-1.ino

#include <FastLED.h>
#include <MicroView.h>
#include <RBD_Timer.h>
#include <RBD_Button.h>

FASTLED_USING_NAMESPACE

// FastLED "100-lines-of-code" demo reel, showing just a few 
// of the kinds of animation patterns you can quickly and easily 
// compose using FastLED.  
//
// This example also shows one easy way to define multiple 
// animations patterns and have them automatically rotate.
//
// -Mark Kriegsman, December 2014


////////////////////
// Pin configuration
////////////////////
#define LED_DATA_PIN  3
#define KNOB_PIN      A1
#define BUTTON_PIN    2


#if FASTLED_VERSION < 3001000
#error "Requires FastLED 3.1 or later; check github for latest code."
#endif


#define LED_TYPE    WS2811
#define COLOR_ORDER GRB
#define NUM_LEDS    50
CRGB leds[NUM_LEDS];

#define BRIGHTNESS          96
#define FRAMES_PER_SECOND  120

MicroViewWidget *widget;    // create widget pointer
uint8_t sensorValue = 0;  // variable to store the value coming from the sensor

// Create a handy Button object
RBD::Button button(BUTTON_PIN); // input_pullup by default

#define ARRAY_SIZE(A) (sizeof(A) / sizeof((A)[0]))

uint8_t gCurrentPatternNumber = 0; // Index number of which pattern is current
uint8_t gHue = 0; // rotating "base color" used by many of the patterns

float underlyingHue = 0.0;

//volatile uint8_t needsChange = 0;

void setup() {
  delay(3000); // 3 second delay for recovery
  
  // tell FastLED about the LED strip configuration
  FastLED.addLeds<LED_TYPE,LED_DATA_PIN,COLOR_ORDER>(leds, NUM_LEDS).setCorrection(TypicalLEDStrip);

  // set master brightness control
  FastLED.setBrightness(BRIGHTNESS);

  /////////////////////////////////
  // Setup for MicroView components
  /////////////////////////////////
  digitalWrite(KNOB_PIN, HIGH);    // Internal Pull-up
  pinMode(KNOB_PIN, INPUT);      // make pin as INPUT

  uView.begin();            // start MicroView
  uView.clear(PAGE);          // clear page
  widget = new MicroViewSlider(0, 20, 0, 1023, WIDGETSTYLE1 + WIDGETNOVALUE);  // make widget as Silder STYLE1
  uView.display();          // display the content in the screen buffer
}

// List of patterns to cycle through.  Each is defined as a separate function below.
typedef void (*SimplePatternList[])();
SimplePatternList gPatterns = { rainbow, rainbowWithGlitter, confetti, sinelon, juggle, bpm };
//SimplePatternList gPatterns = { rainbow };

void nextPattern()
{
  // add one to the current pattern number, and wrap around at the end
  gCurrentPatternNumber = (gCurrentPatternNumber + 1) % ARRAY_SIZE( gPatterns);
}

void loop()
{
  /////////////////////////////////
  // Read and Update MicroView components
  /////////////////////////////////
  sensorValue = 1024 - analogRead(KNOB_PIN);  // read sensorPin
  widget->setValue(sensorValue);     // set value of sensorPin to widget

  uView.setCursor(0,0);
  uView.print(gCurrentPatternNumber);
  uView.setCursor(20,0);

  if (button.onPressed()) {
    uView.print("PRESS");
    nextPattern();
  }

  if (button.onReleased()) {
    uView.print("     ");
  }
 
  uView.display();            // display the content in the screen buffer

  // Call the current pattern function once, updating the 'leds' array
  gPatterns[gCurrentPatternNumber]();

  // send the 'leds' array out to the actual LED strip
  FastLED.show();  
  // insert a delay to keep the framerate modest
  FastLED.delay(1000/FRAMES_PER_SECOND); 

  // do some periodic updates

  // slowly cycle the "base color" through the rainbow
  EVERY_N_MILLISECONDS( 20 ) {
    underlyingHue += (sensorValue / 256.0);
    gHue = underlyingHue;
  } 
  
  //  EVERY_N_SECONDS( 10 ) { nextPattern(); } // change patterns periodically
}


void rainbow() 
{
  // FastLED's built-in rainbow generator
  fill_rainbow( leds, NUM_LEDS, gHue, 7);
}

void rainbowWithGlitter() 
{
  // built-in FastLED rainbow, plus some random sparkly glitter
  rainbow();
  addGlitter(80);
}

void addGlitter( fract8 chanceOfGlitter) 
{
  if( random8() < chanceOfGlitter) {
    leds[ random16(NUM_LEDS) ] += CRGB::White;
  }
}

void confetti() 
{
  // random colored speckles that blink in and fade smoothly
  fadeToBlackBy( leds, NUM_LEDS, 10);
  int pos = random16(NUM_LEDS);
  leds[pos] += CHSV( gHue + random8(64), 200, 255);
}

void sinelon()
{
  // a colored dot sweeping back and forth, with fading trails
  fadeToBlackBy( leds, NUM_LEDS, 20);
  int pos = beatsin16(13,0,NUM_LEDS);
  leds[pos] += CHSV( gHue, 255, 192);
}

void bpm()
{
  // colored stripes pulsing at a defined Beats-Per-Minute (BPM)
  uint8_t BeatsPerMinute = 62;
  CRGBPalette16 palette = PartyColors_p;
  uint8_t beat = beatsin8( BeatsPerMinute, 64, 255);
  for( int i = 0; i < NUM_LEDS; i++) { //9948
    leds[i] = ColorFromPalette(palette, gHue+(i*2), beat-gHue+(i*10));
  }
}

void juggle() {
  // eight colored dots, weaving in and out of sync with each other
  fadeToBlackBy( leds, NUM_LEDS, 20);
  byte dothue = 0;
  for( int i = 0; i < 8; i++) {
    leds[beatsin16(i+7,0,NUM_LEDS)] |= CHSV(dothue, 200, 255);
    dothue += 32;
  }
}