Balanced parentheses checker in a balanced parentheses language

parens.clj

(ns parens)

(defn mk-balanced?
  "makes a balanced? checker from table, which maps closing characters to
  opening characters.

  see also: balanced?"
  [table]
  (fn [s]
    (let [opens (set (vals table))
          closes (set (keys table))]
      (->> s
           seq
           (reduce
            (fn [stack cur]
              (condp contains? cur
                opens (conj stack cur)
                closes (if (and (seq stack)
                                (= (peek stack) (table cur)))
                         (pop stack)
                         (reduced [:false]))
                stack))
            [])
           empty?))))

(def balanced?
  (mk-balanced? {\) \(
                 \] \[
                 \} \{}))

(comment
 (->> "parens.clj"
      slurp
      balanced?) ;=> false

 (->> "parens.clj"
      slurp
      reverse
      (drop 304) ;; length of balanced? form + this comment
      reverse
      balanced?) ;=> true
 )