build_data.bzl

"""gen_build_data: generate build_data from various templates.

This does something very simple: concatenates bazel's stable-status and
volatile-status linkstamp data with an optional header and footer.
"""

def _gen_build_data_impl(ctx):
  cmd = ["cat"]
  inputs = [
      ctx.version_file,  # volatile-status.txt
      ctx.info_file,     # stable-status.txt
  ]

  if ctx.file.header:
    cmd += [ctx.file.header.path]
    inputs += [ctx.file.header]

  cmd += [
      ctx.version_file.path,
      "<(echo)",  # Add a newline in case version_file lacks one at the end
      ctx.info_file.path,
      "<(echo)",  # Same for info_file
  ]

  if ctx.file.footer:
    cmd += [ctx.file.footer.path]
    inputs += [ctx.file.footer]
  cmd += [">", ctx.outputs.gen_src.path]

  ctx.action(
      inputs = inputs,
      outputs = [ctx.outputs.gen_src],
      command = " ".join(cmd),
      mnemonic = "GenBuildData",
  )


gen_build_data = rule(
    _gen_build_data_impl,
    attrs = {
        "header": attr.label(allow_single_file = True),
        "footer": attr.label(allow_single_file = True),
        "out": attr.string(default = "%{name}"),
    },
    outputs = {"gen_src": "%{out}"},
)