PKGBUILD

# Maintainer: Yann Leprince <yann dot leprince at ylep dot fr>
pkgname=blitz
pkgver=0.10
pkgrel=1
pkgdesc="C++ Class library for scientific computing"
arch=('i686' 'x86_64')
url="http://www.sourceforge.net/projects/blitz/"
# The user is free to choose the license among ('Artistic2.0' 'BSD' 'LGPL3'),
# but we cannot express it here so we only mention the most permissive.
license=('BSD')
depends=('boost')
makedepends=()
conflicts=('blitz-cppqed-hg')
source=("git://github.com/blitzpp/blitz.git"
        "blitz-0.10-gcc47.patch"
        "python2.patch")
md5sums=('SKIP'
         '3f1d36d804e0de97b8f090cf2826ca61'
         '721dcc5570f4740d8bf675eb6e057fc5')

prepare() {
  cd "$pkgname"
  patch -p1 -i "$srcdir/blitz-0.10-gcc47.patch"
  patch -p1 -i "$srcdir/python2.patch"
  autoreconf -i
}

build() {
  local _conditional_options
  cd "$pkgname"

  if [ "$CARCH" = "x86_64" ]; then
    _conditional_options=--enable-64bit
  else
    # According to this bug report on
    # https://bugs.launchpad.net/ubuntu/+source/blitz++/+bug/1213144
    # we have to use --enable-simd-width=8
    _conditional_options=--enable-simd-width=8
  fi

  # Fortran is needed for benchmarks only
  ./configure \
      --prefix=/usr \
      --enable-shared \
      --enable-serialization \
      --disable-fortran \
      --disable-cxx-flags-preset \
      ${_conditional_options}

  make LDFLAGS="$LDFLAGS" lib
}

check() {
  cd "$pkgname"
  make -k check-testsuite
}

package() {
  cd "$pkgname"
  install -D -m644 COPYRIGHT "$pkgdir/usr/share/licenses/$pkgname/COPYRIGHT"
  make DESTDIR="$pkgdir/" install || return 1
}

python2.patch

diff --git a/blitz/generate/Makefile.am b/blitz/generate/Makefile.am
index 8ee4003..e958c42 100644
--- a/blitz/generate/Makefile.am
+++ b/blitz/generate/Makefile.am
@@ -9,7 +9,7 @@ EXTRA_DIST = genstencils.py
 EXTRA_PROGRAMS = 
 
 $(top_srcdir)/blitz/array/stencil-classes.cc: genstencils.py
-	python $< $@
+	python2 $< $@
 
 generate-headers: $(top_srcdir)/blitz/array/stencil-classes.cc
 
diff --git a/blitz/generate/genstencils.py b/blitz/generate/genstencils.py
index dc39c1e..16611bd 100644
--- a/blitz/generate/genstencils.py
+++ b/blitz/generate/genstencils.py
@@ -1,4 +1,4 @@
-#!/bin/env python
+#!/usr/bin/env python2
 
 # Generates stencil code. This replaces the macros in stencil-et.h,
 # which make it impossible to debug the generated code.
diff --git a/blitz/generate/makeloops.py b/blitz/generate/makeloops.py
index 77e8a85..c740aaa 100755
--- a/blitz/generate/makeloops.py
+++ b/blitz/generate/makeloops.py
@@ -1,4 +1,4 @@
-#!/usr/bin/env python
+#!/usr/bin/env python2
 
 # python version of the makeloops.cpp that generates the benchmark
 # loops.