qspectrumanalyzer.nix

{ lib, fetchFromGitHub
, python3
, soapysdr
}:

let

  qtdotpy = python3.pkgs.buildPythonPackage rec {
    pname = "Qt.py";
    version = "1.3.2";

    src = fetchFromGitHub {
      owner = "mottosso";
      repo = "Qt.py";
      rev = version;
      sha256 = "0py2cv92qxs3ym37wccc69np202jd7s0pdjw0m1wvsw68qvk6ykf";
    };

    doCheck = false;

    meta = with lib; {
      homepage = "https://github.com/mottosso/Qt.py";
      description = "Python 2 & 3 compatibility wrapper around all Qt bindings";
      license = licenses.mit;
      platforms = platforms.linux;
    };
  };

  simplesoapy = python3.pkgs.buildPythonPackage rec {
    pname = "simplesoapy";
    version = "1.5.1";

    src = fetchFromGitHub {
      owner = "xmikos";
      repo = pname;
      rev = "v${version}";
      sha256 = "1nzp1n5z9s7mdhhh1ag35pdzdjv79x6hgrvi3shb49cjxv3k30kk";
    };

    propagatedBuildInputs = with python3.pkgs; [
      numpy
      soapysdr
    ];

    doCheck = false;

    meta = with lib; {
      homepage = "https://github.com/xmikos/simplesoapy";
      description = "Simple pythonic wrapper for SoapySDR library";
      license = licenses.mit;
      platforms = platforms.linux;
    };
  };

  simplespectral = python3.pkgs.buildPythonPackage rec {
    pname = "simplespectral";
    version = "1.0.0";

    src = fetchFromGitHub {
      owner = "xmikos";
      repo = pname;
      rev = "v${version}";
      sha256 = "1x59qxpl2f82m535pgqn23c5yvixp2nwmjnavsjmqps9z1dxcphy";
    };

    propagatedBuildInputs = with python3.pkgs; [
      numpy
    ];

    meta = with lib; {
      homepage = "https://github.com/xmikos/simplespectral";
      description = ''
        Heavily simplified scipy.signal.spectral module
        which only depends on NumPy and supports pyFFTW
      '';
      license = licenses.mit;
      platforms = platforms.linux;
    };
  };

  soapy_power = python3.pkgs.buildPythonPackage rec {
    pname = "soapy_power";
    version = "1.6.1";

    src = fetchFromGitHub {
      owner = "xmikos";
      repo = pname;
      rev = "v${version}";
      sha256 = "178n2jp1li25aqb30w1dbq68vh5zfzg207r3swzjyisf9pmrv6lj";
    };

    propagatedBuildInputs = with python3.pkgs; [
      numpy
      simplesoapy
      simplespectral
    ];

    doCheck = false;

    meta = with lib; {
      homepage = "https://github.com/xmikos/soapy_power";
      description = "Obtain power spectrum from SoapySDR devices";
      license = licenses.mit;
      platforms = platforms.linux;
    };
  };

in

python3.pkgs.buildPythonApplication rec {
  pname = "qspectrumanalyzer";
  version = "2.2.0";

  src = fetchFromGitHub {
    owner = "xmikos";
    repo = pname;
    rev = "v${version}";
    sha256 = "0vpi981m2xsmksxy2m08hpi5h3rayq3kaxlf8iry4r988p45lirs";
  };

  propagatedBuildInputs = with python3.pkgs; [
    qtdotpy
    pyqtgraph
    soapy_power
  ];

  doCheck = false;

  meta = with lib; {
    description = "Spectrum analyzer for multiple SDR platforms";
    homepage = "https://github.com/xmikos/qspectrumanalyzer";
    license = licenses.gpl3Plus;
    platforms = platforms.linux;
  };
}