README.md

Negative script for Capture One

This script allows you to invert negatives scanned with a camera in Capture One 20 (please adapt the script for other versions).

How to use

You need Capture One on Mac, as scripts are not supported in Windows version.

1. Put the script in the scripts folder (access through Scripts > Open Scripts folder) then Scripts > Update Scripts menu.
2. Set the level tool to R, G and B channels: menu Preferences... > Exposure > Level tools > Channel mode: set to "Red, Green and Blue channels"
3. Crop the photo you want to invert to exclude the frame
4. Call the script from the scripts menu

Post-processing

The script sets the curce to "linear response". So the photo will look flat. Adjust the constrast/curve to your taste.

Notes

• Don't forget to revert the channel mode once you're done!
• You can select multiple photos to process at once.
• If the photo is not cropped, the results won't be good.

Negative.applescript

tell application "Capture One 20"
	set imageNames to ""
	
	repeat with variantItem in (get selected variants)
		-- Set the white balance to 2400K, -12 tint
		set adj to (get adjustments of variantItem)
		set temperature of adj to 2400
		set tint of adj to -12

		-- Set linear curve
		set film curve of adj to "Linear Response"

		-- Autoadjust levels
		-- For best results, in Capture One, in Preferences... -> Exposure -> Level Tool, Channel mode must be set to "Red, Green and Blue Channels"
		autoadjust variantItem without adjust white balance, adjust exposure, adjust contrast brightness, adjust hdr, adjust rotation and adjust keystone
		
		-- Negate the image
		set adj to (get adjustments of variantItem)
		
		-- Red level
		set redLevel to (get level highlight red of adj)
		set level highlight red of adj to (get level shadow red of adj)
		set level shadow red of adj to redLevel
		-- Green level
		set greenLevel to (get level highlight green of adj)
		set level highlight green of adj to (get level shadow green of adj)
		set level shadow green of adj to greenLevel
		-- Blue level
		set blueLevel to (get level highlight blue of adj)
		set level highlight blue of adj to (get level shadow blue of adj)
		set level shadow blue of adj to blueLevel
		
		-- Create a new layer and apply gamma style to it
		
	end repeat
	
end tell