dump-doc.lisp

(in-package #:cl-user)

(defun display-doc-of-package-exports (package)
  "Simple code to display the documenation for a package's exports."
  (flet ((arglist (sym)
           #+ccl (ccl:arglist sym)
           #-ccl ()))
    (let ((*package* (find-package package)))
      (do-external-symbols (s *package*)
        (loop
           for doc-type in '(function        variable
                             compiler-macro  setf        method-combination
                             type            structure)
           as doc = (documentation s doc-type)
           when doc do
             (format t "~2&== ~@(~A~): ~A~@[ ~A~]~&~A"
                     (if (eq 'function doc-type)
                         (cond
                           ((macro-function s) 'macro)
                           ((special-operator-p s) 'special)
                           (t doc-type))
                         doc-type)
                     s
                     (case doc-type
                       ((method-combination function compiler-macro)
                        (arglist s)))
                     doc))))))