spring-boot-project-basic.gradle

plugins {
    id 'java'
}

repositories {
    mavenCentral()
}

dependencies {
    implementation platform("org.springframework.boot:spring-boot-dependencies:2.0.5.RELEASE")
    implementation "org.springframework.boot:spring-boot-starter-data-jpa"

    // Use a newer version of the spring-data-releasetrain
    implementation platform("org.springframework.data:spring-data-releasetrain:Lovelace-RELEASE")
}

spring-boot-project-enforced.gradle

plugins {
    id 'java'
}

repositories {
    mavenCentral()
}

dependencies {
    implementation enforcedPlatform("org.springframework.boot:spring-boot-dependencies:2.0.5.RELEASE")
    implementation "org.springframework.boot:spring-boot-starter-data-jpa"

    // Use a newer version of the spring-data-releasetrain.
    implementation enforcedPlatform("org.springframework.data:spring-data-releasetrain:Lovelace-RELEASE")

    // Remove any of the dependencies declared in `spring-data-releasetrain` from `spring-boot-dependencies`.
    // Note that this looks simple here, because we assume they all have a matching group.
    // This may not be the case.
    components {
        withModule("org.springframework.boot:spring-boot-dependencies") {
            allVariants {
                withDependencyConstraints { deps ->
                    deps.removeAll { it.group == 'org.springframework.data' }
                }
            }
        }
    }
}