dibbler-client/radvd integrator

radvd-update.pl

#!/usr/bin/perl

use warnings;
use strict;

use File::Compare;

open(my $dib, "/etc/dibbler/radvd.conf") or die "Failed to open dibbler config: $!";

my $int; # current interface
my $start; # used to skip non-prefix lines from dibbler
my %ints;
while(<$dib>) {
	chomp;
	if(/^{/ or /^\s*($|#)/) {
		next;
	} elsif(/^};/) {
		$int = undef;
		$start = undef;
	} elsif(/^interface\s*(\S*)\s*/) {
		$int = $1;
	} else {
		$start = 1 if(/prefix/);
		next if !$start;
		s/     /\t/; # 5 space tabs? wat
		s/    /\t/g;
		$ints{$int} .= "$_\n";
		# adding options dibbler doesn't add
		$ints{$int} .= "\t\tDeprecatePrefix on;\n\t\tAdvRouterAddr on;\n"
			if(/prefix/);
	}
}

close $dib;

open(my $newrad, ">", "/etc/radvd.conf.tmp") or die "Failed to open new radvd config: $!";

open(my $rad, "/etc/radvd.conf") or die "Failed to open radvd config: $!";

my $skip; # used to skip previous dibbler conf
while(<$rad>) {
	print $newrad $_ if !$skip;
	chomp;
	if(/^interface\s*(\S*)\s*/) {
		$int = $1;
	} elsif(/#dibbler/) {
		$skip = !$skip;
		print $newrad $ints{$int}
			if $skip && exists $ints{$int};
		print $newrad "$_\n"
			if !$skip;
	}
}

close $rad;

close $newrad or die "Failed to close new radvd config: $!";

if(!compare("/etc/radvd.conf.tmp", "/etc/radvd.conf")) {
	unlink("/etc/radvd.conf.tmp");
	exit;
}

rename("/etc/radvd.conf.tmp", "/etc/radvd.conf")
	or die "Failed to rename new to old: $!";

exec("pkill -HUP -o radvd")
	or die "Failed to exec pkill: $!";