PKGBUILD for lib32-openmotif

PKGBUILD

# $Id$
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Enrico Morelli <morelli@cerm.unifi.it>

pkgname=lib32-openmotif
pkgver=2.3.8
pkgrel=1
pkgdesc="Open Motif"
arch=('x86_64')
url="https://motif.ics.com/"
license=('LGPL')
depends=(lib32-libjpeg-turbo lib32-libxft lib32-libxmu lib32-libxp)
makedepends=(xbitmaps xproto printproto xextproto automake lib32-flex)
conflicts=(lesstif)
source=("https://downloads.sourceforge.net/project/motif/Motif%20$pkgver%20Source%20Code/motif-$pkgver.tar.gz")
md5sums=('7572140bb52ba21ec2f0c85b2605e2b1')

build() {
  cd motif-$pkgver
  export LDFLAGS="-lX11"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  ./configure --enable-dependency-tracking --prefix=/usr --libdir=/usr/lib32 --host=i686-pc-linux-gnu --libexecdir=/usr/lib32
  make -j2
}

package() {
  cd motif-$pkgver
  make DESTDIR="$pkgdir" install
  rm -rf "${pkgdir}/usr/share"
  rm -rf "${pkgdir}/usr/include"
  rm -rf "${pkgdir}/usr/bin"
}